【CF645D】 Robot Rapping Results Report（拓扑排序，二分）

题意：有一张N点M边的有向图，求最小的K使根据前K条边就能够确定图是否有唯一的拓扑序，

        若没有唯一拓扑序输出-1

思路：二分答案再拓扑排序，以入度为0的节点作为新的一层，若某一层的节点个数<>1则没有唯一拓扑序

var head,vet,next,d,x,y,b:array[1..210000]of longint;
    n,m,i,l,r,mid,last,tot:longint;

procedure add(a,b:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 head[a]:=tot;
end;

function isok(len:longint):boolean;
var s,e,i,st,v:longint;
begin
 fillchar(head,sizeof(head),0);
 fillchar(b,sizeof(b),0);
 fillchar(d,sizeof(d),0);
 tot:=0;
 for i:=1 to len do
 begin
  add(x[i],y[i]);
  inc(d[y[i]]);
 end;
 s:=0;
 for i:=1 to n do
  if d[i]=0 then begin st:=i; b[i]:=1; inc(s); end;
 if s<>1 then exit(false);
 for i:=1 to n-1 do
 begin
  e:=head[st];
  while e<>0 do
  begin
   v:=vet[e];
   dec(d[v]);
   e:=next[e];
  end;
  e:=head[st]; s:=0;
  while e<>0 do
  begin
   v:=vet[e];
   if (d[v]=0)and(b[v]=0) then
   begin
    inc(s); b[v]:=1; st:=v;
   end;
   e:=next[e];
  end;
  if s<>1 then exit(false);
 end;
 exit(true);
end;

begin
// assign(input,'cf645D.in'); reset(input);
// assign(output,'cf645D.out'); rewrite(output);
 readln(n,m);
 for i:=1 to m do readln(x[i],y[i]);
 l:=1; r:=m; last:=m+1;
 while l<=r do
 begin
  mid:=(l+r)>>1;
  if isok(mid) then begin last:=mid; r:=mid-1; end
   else l:=mid+1;
 end;
 if last=m+1 then writeln(-1)
  else writeln(last);
 //close(input);
// close(output);
end.