【HDOJ2196】Computer（树的直径，树形DP）

题意：给定一棵N个点树，询问这个树里面每个点到树上其他点的最大距离。

n<=10000

思路：设f[u,1],f[u,2]为以U为根向下的最长与次长，g[u,1],g[u,2]为从哪个儿子转移来

         第一次dfs用V更新U，第二次dfs用U更新V，因为有V向U往上走的情况，这样做就可以处理了

         可以发现这些数值中取最大值就是树的直径了

var f,g:array[1..21000,1..2]of longint;
    head,vet,next,len:array[1..21000]of longint;
    n,x,y,i,tot:longint;

procedure add(a,b,c:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 len[tot]:=c;
 head[a]:=tot;
end;

procedure dfs(u,fa:longint);
var e,v,t:longint;
begin
 e:=head[u];
 while e<>0 do
 begin
  v:=vet[e];
  if v<>fa then
  begin
   dfs(v,u);
   t:=f[v,1]+len[e];
   if t>f[u,1] then
   begin
    f[u,2]:=f[u,1]; g[u,2]:=g[u,1];
    f[u,1]:=t; g[u,1]:=v;
   end
    else if t>f[u,2] then
    begin
     f[u,2]:=t; g[u,2]:=v;
    end;
  end;
  e:=next[e];
 end;
end;

procedure dfs2(u,fa:longint);
var e,v,t:longint;
begin
 e:=head[u];
 while e<>0 do
 begin
  v:=vet[e];
  if v<>fa then
  begin
   t:=f[u,1]+len[e];
   if v=g[u,1] then t:=f[u,2]+len[e];
   if t>f[v,1] then
   begin
    f[v,2]:=f[v,1]; g[v,2]:=g[v,1];
    f[v,1]:=t; g[v,1]:=u;
   end
    else if t>f[v,2] then
    begin
     f[v,2]:=t; g[v,2]:=u;
    end;
   dfs2(v,u);
  end;
  e:=next[e];
 end;
end;

begin
 assign(input,'2196.in'); reset(input);
 assign(output,'2196.out'); rewrite(output);
 while not eof do
 begin
  fillchar(head,sizeof(head),0);
  tot:=0;
  fillchar(f,sizeof(f),0);
  fillchar(g,sizeof(g),0);
  read(n);
  if n=0 then break;
  for i:=2 to n do
  begin
   read(x,y);
   add(i,x,y);
   add(x,i,y);
  end;
  dfs(1,-1);
  dfs2(1,-1);
  for i:=1 to n do writeln(f[i,1]);
 end;
 close(input);
 close(output);
end.