【BZOJ2243】染色（树链剖分）

题意：

给定一棵有n个节点的无根树和m个操作，操作有2类：

1、将节点a到节点b路径上所有点都染成颜色c；

2、询问节点a到节点b路径上的颜色段数量（连续相同颜色被认为是同一段），如“112221”由3段组成：“11”、“222”和“1”。

请你写一个程序依次完成这m个操作。

数N<=10^5，操作数M<=10^5，所有的颜色C为整数且在[0, 10^9]之间。

思路：树上的路径染色问题可以用树剖解决。

        对于线段树的某个节点我们记录以下信息：最左端颜色，最右端颜色，整段中段数，以及lazytag。

        其中lazytag>=0时表示该区间要改成什么颜色，-1表示当前节点没有标记。

        转换到树上做即可

        BZOJ过了样例就一遍过（萎靡）

type un=record
         l,r,s,tag:longint;
        end;
var t:array[1..500000]of un;
    f:array[1..110000,0..18]of longint;
    head,vet,next,flag,dep,fa,top,
    tid,id,size,son,a:array[1..210000]of longint;
    n,m,i,j,k,x,y,z,q,tot,time:longint;
    ch:string;
    emp:un;

procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;

procedure add(a,b:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 head[a]:=tot;
end;

procedure dfs1(u:longint);
var e,v,maxsize,i:longint;
begin
 flag[u]:=1; size[u]:=1; maxsize:=0; son[u]:=0;
 for i:=1 to 18 do
 begin
  if dep[u]<(1<<i) then break;
  f[u,i]:=f[f[u,i-1],i-1];
 end;

 e:=head[u];
 while e<>0 do
 begin
  v:=vet[e];
  if flag[v]=0 then
  begin
   dep[v]:=dep[u]+1;
   f[v,0]:=u;
   fa[v]:=u;
   dfs1(v);
   size[u]:=size[u]+size[v];
   if size[v]>maxsize then
   begin
    maxsize:=size[v];
    son[u]:=v;
   end;
  end;
  e:=next[e];
 end;
end;

procedure dfs2(u,ance:longint);
var e,v:longint;
begin
 flag[u]:=1; inc(time); tid[u]:=time; id[time]:=u; top[u]:=ance;
 if son[u]>0 then dfs2(son[u],ance);
 e:=head[u];
 while e<>0 do
 begin
  v:=vet[e];
  if flag[v]=0 then dfs2(v,v);
  e:=next[e];
 end;
end;

function lca(x,y:longint):longint;
var i,d:longint;
begin
 if dep[x]<dep[y] then swap(x,y);
 d:=dep[x]-dep[y];
 for i:=0 to 18 do
  if d and (1<<i)>0 then x:=f[x,i];
 for i:=18 downto 0 do
  if f[x,i]<>f[y,i] then
  begin
   x:=f[x,i]; y:=f[y,i];
  end;
 if x=y then exit(x);
 exit(f[x,0]);
end;

procedure pushup(p:longint);
begin
 t[p].l:=t[p<<1].l; t[p].r:=t[p<<1+1].r;
 if t[p<<1].r<>t[p<<1+1].l then t[p].s:=t[p<<1].s+t[p<<1+1].s
  else t[p].s:=t[p<<1].s+t[p<<1+1].s-1;
end;

procedure pushdown(p,l,r:longint);
var tmp:longint;
begin
 tmp:=t[p].tag; t[p].tag:=-1;
 if (tmp=-1)or(l=r) then exit;
 t[p<<1].s:=1; t[p<<1+1].s:=1;
 t[p<<1].tag:=tmp; t[p<<1+1].tag:=tmp;
 t[p<<1].l:=tmp; t[p<<1].r:=tmp;
 t[p<<1+1].l:=tmp; t[p<<1+1].r:=tmp;
end;

procedure build(l,r,p:longint);
var mid:longint;
begin
 if l=r then
 begin
  t[p].s:=1;
  t[p].tag:=-1;
  exit;
 end;
 t[p].tag:=-1;
 mid:=(l+r)>>1;
 build(l,mid,p<<1);
 build(mid+1,r,p<<1+1);
end;

procedure update(l,r,x,y,v,p:longint);
var mid:longint;
begin
 pushdown(p,l,r);
 if (l>=x)and(r<=y) then
 begin
  t[p].l:=v; t[p].r:=v;
  t[p].s:=1; t[p].tag:=v;
  exit;
 end;
 mid:=(l+r)>>1;
 if x<=mid then update(l,mid,x,y,v,p<<1);
 if y>mid then update(mid+1,r,x,y,v,p<<1+1);
 pushup(p);
end;

function query(l,r,x,y,p:longint):longint;
var mid,t1,t2:longint;
begin
 pushdown(p,l,r);
 if (l>=x)and(r<=y) then exit(t[p].s);
 mid:=(l+r)>>1;
 t1:=0; t2:=0;
 if x<=mid then t1:=query(l,mid,x,y,p<<1);
 if y>mid then t2:=query(mid+1,r,x,y,p<<1+1);
 if t1=0 then exit(t2);
 if t2=0 then exit(t1);
 query:=t1+t2;
 if t[p<<1].r=t[p<<1+1].l then dec(query);
end;

function get(l,r,x,p:longint):longint;
var mid:longint;
begin
 pushdown(p,l,r);
 if (l=x)and(r=x) then exit(t[p].l);
 mid:=(l+r)>>1;
 if x<=mid then exit(get(l,mid,x,p<<1))
  else exit(get(mid+1,r,x,p<<1+1));
end;

function ask(x,y:longint):longint;
var q:longint;
begin
 q:=lca(x,y);
 ask:=0;
 while top[x]<>top[q] do
 begin
  ask:=ask+query(1,n,tid[top[x]],tid[x],1);
  if get(1,n,tid[top[x]],1)=get(1,n,tid[fa[top[x]]],1) then dec(ask);
  x:=fa[top[x]];
 end;
 ask:=ask+query(1,n,tid[q],tid[x],1);
 while top[y]<>top[q] do
 begin
  ask:=ask+query(1,n,tid[top[y]],tid[y],1);
  if get(1,n,tid[top[y]],1)=get(1,n,tid[fa[top[y]]],1) then dec(ask);
  y:=fa[top[y]];
 end;
 ask:=ask+query(1,n,tid[q],tid[y],1);
 dec(ask);

end;

procedure solve(x,y,z:longint);
var q:longint;
begin
 q:=lca(x,y);
 while top[x]<>top[q] do
 begin
  update(1,n,tid[top[x]],tid[x],z,1);
  x:=fa[top[x]];
 end;
 update(1,n,tid[q],tid[x],z,1);
 while top[y]<>top[q] do
 begin
  update(1,n,tid[top[y]],tid[y],z,1);
  y:=fa[top[y]];
 end;
 update(1,n,tid[q],tid[y],z,1);
end;

begin
 assign(input,'bzoj2243.in'); reset(input);
 assign(output,'bzoj2243.out'); rewrite(output);
 readln(n,m);
 for i:=1 to n do read(a[i]);
 for i:=1 to n-1 do
 begin
  readln(x,y);
  add(x,y);
  add(y,x);
 end;
 dfs1(1);
 fillchar(flag,sizeof(flag),0);
 dfs2(1,1);
 build(1,n,1);
 for i:=1 to n do update(1,n,tid[i],tid[i],a[i],1);
 //for i:=1 to n do write(a[id[i]],' ');
 for i:=1 to m do
 begin
  readln(ch);
  x:=0; y:=0; z:=0;
  case ch[1] of
   'C':
   begin
    for k:=3 to length(ch) do
    begin
     if ch[k]=' ' then break;
     x:=x*10+ord(ch[k])-ord('0');
    end;
    j:=k+1;
    for k:=j to length(ch) do
    begin
     if ch[k]=' ' then break;
     y:=y*10+ord(ch[k])-ord('0');
    end;
    j:=k+1;
    for k:=j to length(ch) do z:=z*10+ord(ch[k])-ord('0');
    solve(x,y,z);
   end;

   'Q':
   begin
    for k:=3 to length(ch) do
    begin
     if ch[k]=' ' then break;
     x:=x*10+ord(ch[k])-ord('0');
    end;
    j:=k+1;
    for k:=j to length(ch) do y:=y*10+ord(ch[k])-ord('0');
    writeln(ask(x,y));
   end;
  end;
 end;
 close(input);
 close(output);
end.