【POJ3321】Apple Tree（DFS序，树状数组）

题意：给一棵n个节点的树，每个节点开始有一个苹果，m次操作

1.将某个结点的苹果数异或 1

2.查询一棵子树内的苹果数

n,m<=100000

 

思路：最近一段时间在思考树上统计问题的算法

发现询问一棵子树中信息的问题一般都是DFS序+线段树或BIT维护

树上两点之间的查询一般都是树剖维护

比如说这题，单点修改+区间查询子树信息，转化为DFS序用BIT维护即可

注意有一个性质：U在DFS序中第一次出现的时刻是b[u]，则它的子树就是区间(b[u],b[u]+size[u]-1)

var t:array[0..1000000]of longint;
    head,vet,next,a,b,c,size,flag:array[1..500000]of longint;
    n,m,x,y,i,j,tot,time,p:longint;
    ch:string;

procedure add(a,b:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 head[a]:=tot;
end;

procedure dfs(u:longint);
var e,v:longint;
begin
 flag[u]:=1;
 inc(time); a[time]:=u; b[u]:=time; size[u]:=1;
 e:=head[u];
 while e<>0 do
 begin
  v:=vet[e];
  if flag[v]=0 then
  begin
   dfs(v);
   size[u]:=size[u]+size[v];
  end;
  e:=next[e];
 end;
end;

function lowbit(x:longint):longint;
begin
 exit(x and (-x));
end;

procedure update(x,p:longint);
begin
 while x<=n do
 begin
  t[x]:=t[x]+p;
  x:=x+lowbit(x);
 end;
end;

function sum(x:longint):longint;
begin
 sum:=0;
 while x>0 do
 begin
  sum:=sum+t[x];
  x:=x-lowbit(x);
 end;
end;

begin
 assign(input,'poj3321.in'); reset(input);
 assign(output,'poj3321.out'); rewrite(output);
 readln(n);
 for i:=1 to n-1 do
 begin
  readln(x,y);
  add(x,y);
  add(y,x);
 end;
 dfs(1);
 for i:=1 to n do
 begin
  c[i]:=1;
  update(b[i],1);
 end;
 readln(m);
 for i:=1 to m do
 begin
  readln(ch);
  x:=0;
  for j:=3 to length(ch) do x:=x*10+ord(ch[j])-ord('0');
  if ch[1]='C' then
  begin
   if c[x]=1 then p:=-1
    else p:=1;
   update(b[x],p);
   c[x]:=c[x] xor 1;
  end;
  if ch[1]='Q' then writeln(sum(b[x]+size[x]-1)-sum(b[x]-1));
 end;
 close(input);
 close(output);
end.