【Codevs1922&网络流24题】骑士共存问题（最小割）

题意：

在一个n*n个方格的国际象棋棋盘上，马（骑士）可以攻击的棋盘方格如图所示。棋盘
上某些方格设置了障碍，骑士不得进入。

对于给定的n*n个方格的国际象棋棋盘和障碍标志，计算棋盘上最多可以放置多少个骑士，使得它们彼此互不攻击。

n<=200,m<=n^2

思路：经典的二分图最大独立集，采用黑白点染色的思想。

如果按照相邻点黑白不同染色，可以发现每次跳到的点必定与现在所在点不同色，二分图最大匹配即可。

每切断一条黑白点之间的边就是少放了一个骑士，用最小割算出最少要切断几条边，总数减去有障碍的再减切断的边数就是最大匹配数，最大独立集又可以转化为最大匹配数。

这里用最小割来解决，因为不能允许任何黑白点之间的任何一条边有流量，符合最小割的思想。

const dx:array[1..8]of longint=(-2,-2,-1,-1,1,1,2,2);
      dy:array[1..8]of longint=(-1,1,-2,2,-2,2,-1,1);
var head,vet,next,len,fan,gap,dis:array[0..500000]of longint;
    b,num,a:array[1..300,1..300]of longint;
    n,m,i,tot,x,y,k,j,source,src,s:longint;

procedure add(a,b,c:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 len[tot]:=c;
 head[a]:=tot;
end;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

function dfs(u,aug:longint):longint;
var e,v,val,flow,t:longint;
begin
 if u=src then exit(aug);
 flow:=0; val:=s-1;
 e:=head[u];
 while e<>0 do
 begin
  v:=vet[e];
  if len[e]>0 then
  begin
   if dis[u]=dis[v]+1 then
   begin
    t:=dfs(v,min(len[e],aug-flow));
    len[e]:=len[e]-t;
    len[fan[e]]:=len[fan[e]]+t;
    flow:=flow+t;
    if dis[source]>=s then exit(flow);
    if aug=flow then break;
   end;
   val:=min(val,dis[v]);
  end;
  e:=next[e];
 end;
 if flow=0 then
 begin
  dec(gap[dis[u]]);
  if gap[dis[u]]=0 then dis[source]:=s;
  dis[u]:=val+1;
  inc(gap[dis[u]]);
 end;
 exit(flow);
end;

function maxflow:longint;
var ans:longint;
begin
 fillchar(gap,sizeof(gap),0);
 fillchar(dis,sizeof(dis),0);
 gap[0]:=s; ans:=0;
 while dis[source]<s do ans:=ans+dfs(source,maxlongint);
 exit(ans);
end;

begin
 assign(input,'codevs1922.in'); reset(input);
 assign(output,'codevs1922.out'); rewrite(output);
 read(n,m);
 for i:=1 to n do
  for j:=1 to n do
  begin
   inc(s); a[i,j]:=(i+j+1) mod 2; num[i,j]:=s;
  end;
 for i:=1 to m do
 begin
  read(x,y);
  b[x,y]:=1;
 end;
 s:=n*n+2;
 for i:=1 to n do
  for j:=1 to n do
   if (a[i,j]=1)and(b[i,j]=0) then
   begin
    for k:=1 to 8 do
    begin
     x:=i+dx[k]; y:=j+dy[k];
     if (x>0)and(x<=n)and(y>0)and(y<=n)and(b[x,y]=0) then
     begin
      fan[tot+2]:=tot+1;
      fan[tot+1]:=tot+2;
      add(num[i,j],num[x,y],1);
      add(num[x,y],num[i,j],0);
     end;
    end;
   end;
 source:=50000; src:=50001;
 for i:=1 to n do
  for j:=1 to n do
   if a[i,j]=1 then
    begin
     fan[tot+2]:=tot+1;
     fan[tot+1]:=tot+2;
     add(source,num[i,j],1);
     add(num[i,j],source,0);
    end
     else if b[i,j]=0 then
     begin
      fan[tot+2]:=tot+1;
      fan[tot+1]:=tot+2;
      add(num[i,j],src,1);
      add(src,num[i,j],0);
     end;
 writeln(n*n-m-maxflow);
 close(input);
 close(output);
end.