【POJ3237】Tree（树链剖分）

题意：在一棵N个节点，有边权的树上维护以下操作：

1：单边修改，将第X条边的边权修改成Y

2：区间取反，将点X与Y在树上路径中的所有边边权取反

3：区间询问最大值，询问X到Y树上路径中边权最大值

n<=10000 CAS<=20

思路：做了2天，改出来的一刻全身都萎掉了

边权转点权，点权就是它到父亲的边的边权，加一些反向标记

取反的标记TAG下传时不能直接赋值为-1，而是将原先的标记取反

多组数据时倍增数组，深度也需要清零

树链剖分不能取第一条边，需要+1

const oo=2000000000;
var t:array[1..100000]of record
                          min,max,tag:longint;
                         end;
    f:array[0..30000,0..15]of longint;
    head,vet,next,dep,tid,id,flag,
    len,son,size,top,a,b,c,d,g,h:array[1..30000]of longint;
    n,m,i,tot,x,y,k,v,cas,time,z,s,tmp,fuhao:longint;
    ch:string;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

function max(x,y:longint):longint;
begin
 if x>y then exit(x);
 exit(y);
end;

procedure add(a,b,c:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 len[tot]:=c;
 head[a]:=tot;
end;

procedure dfs(u:longint);
var e,v,i,t:longint;
begin
 for i:=1 to 15 do
 begin
  if dep[u]<(1<<i) then break;
  f[u,i]:=f[f[u,i-1],i-1];
 end;
 e:=head[u]; flag[u]:=1; size[u]:=1; son[u]:=0; t:=0;
 while e<>0 do
 begin
  v:=vet[e];
  if flag[v]=0 then
  begin
   dep[v]:=dep[u]+1;
   f[v,0]:=u;
   dfs(v);
   size[u]:=size[u]+size[v];
   if size[v]>t then
   begin
    t:=size[v]; son[u]:=v;
   end;
  end;
  e:=next[e];
 end;
end;

procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;

function lca(x,y:longint):longint;
var i,d:longint;
begin
 if dep[x]<dep[y] then swap(x,y);
 d:=dep[x]-dep[y];
 for i:=0 to 15 do
  if d and (1<<i)>0 then x:=f[x,i];
 for i:=15 downto 0 do
  if f[x,i]<>f[y,i] then
  begin
   x:=f[x,i]; y:=f[y,i];
  end;
 if x=y then exit(x);
 exit(f[x,0]);
end;

procedure pushdown(l,r,p:longint);
var mid,tmp,t1,t2:longint;
begin
 tmp:=t[p].tag;
 if (l=r)or(tmp=0) then exit;
 t[p].tag:=0;
 t1:=t[p<<1].min; t2:=t[p<<1].max;
 t[p<<1].max:=-t1; t[p<<1].min:=-t2;
 t1:=t[p<<1+1].min; t2:=t[p<<1+1].max;
 t[p<<1+1].max:=-t1; t[p<<1+1].min:=-t2;
 t[p<<1].tag:=-1-t[p<<1].tag; t[p<<1+1].tag:=-1-t[p<<1+1].tag;

end;

procedure pushup(p:longint);
begin
 t[p].min:=min(t[p<<1].min,t[p<<1+1].min);
 t[p].max:=max(t[p<<1].max,t[p<<1+1].max);
end;

procedure change(l,r,x,v,p:longint);
var mid:longint;
begin
 pushdown(l,r,p);
 if (l=x)and(r=x) then
 begin
  t[p].min:=v; t[p].max:=v;
 // t[p].tag:=v;
  exit;
 end;
 mid:=(l+r)>>1;
 if x<=mid then change(l,mid,x,v,p<<1)
  else change(mid+1,r,x,v,p<<1+1);
 pushup(p);
end;

procedure dfs2(u,ance:longint);
var e,v:longint;
begin
 flag[u]:=1; inc(time); tid[u]:=time; id[time]:=u; top[u]:=ance;
 if son[u]>0 then dfs2(son[u],ance);
 e:=head[u];
 while e<>0 do
 begin
  v:=vet[e];
  if flag[v]=0 then dfs2(v,v);
  e:=next[e];
 end;
end;

procedure build(l,r,p:longint);
var mid:longint;
begin
 if l=r then
 begin
  if h[id[l]]>oo then
  begin
   t[p].min:=oo; t[p].max:=-oo;
  end
   else begin t[p].min:=h[id[l]]; t[p].max:=h[id[l]]; end;
  t[p].tag:=0;
  exit;
 end;
 mid:=(l+r)>>1;
 build(l,mid,p<<1);
 build(mid+1,r,p<<1+1);
 pushup(p);
end;

function query(l,r,x,y,p:longint):longint;
var mid,t1,t2:longint;
begin
 pushdown(l,r,p);
 if (l>=x)and(r<=y) then exit(t[p].max);
 mid:=(l+r)>>1; query:=-oo;
 if x<=mid then query:=max(query,query(l,mid,x,y,p<<1));
 if y>mid then query:=max(query,query(mid+1,r,x,y,p<<1+1));
 pushup(p);
end;

procedure negate(l,r,x,y,p:longint);
var mid,t1,t2:longint;
begin
 pushdown(l,r,p);
 if (l>=x)and(r<=y) then
 begin
  t1:=t[p].min; t2:=t[p].max;
  t[p].min:=-t2; t[p].max:=-t1;
  t[p].tag:=-1;
  exit;
 end;
 mid:=(l+r)>>1;
 if x<=mid then negate(l,mid,x,y,p<<1);
 if y>mid then negate(mid+1,r,x,y,p<<1+1);
 pushup(p);
end;

procedure ngt(x,y:longint);
var q:longint;
begin
 q:=lca(x,y);
 while top[x]<>top[q] do
 begin
  negate(1,n,tid[top[x]],tid[x],1);
  x:=f[top[x],0];
 end;
 if tid[q]+1<=tid[x] then negate(1,n,tid[q]+1,tid[x],1);
 while top[y]<>top[q] do
 begin
  negate(1,n,tid[top[y]],tid[y],1);
  y:=f[top[y],0];
 end;
 if tid[q]+1<=tid[y] then negate(1,n,tid[q]+1,tid[y],1);
end;

function ask(x,y:longint):longint;
var q:longint;
begin
 q:=lca(x,y);
 ask:=-oo;
 while top[x]<>top[q] do
 begin
  ask:=max(ask,query(1,n,tid[top[x]],tid[x],1));
  x:=f[top[x],0];
 end;
 if tid[q]+1<=tid[x] then ask:=max(ask,query(1,n,tid[q]+1,tid[x],1));
 while top[y]<>top[q] do
 begin
  ask:=max(ask,query(1,n,tid[top[y]],tid[y],1));
  y:=f[top[y],0];
 end;
 if tid[q]+1<=tid[y] then ask:=max(ask,query(1,n,tid[q]+1,tid[y],1));
end;

begin
 assign(input,'tree.in'); reset(input);
 assign(output,'poj3237.out'); rewrite(output);
 readln(cas);
 for v:=1 to cas do
 begin
  readln(n);
  fillchar(head,sizeof(head),0); tot:=0; time:=0;
  fillchar(flag,sizeof(flag),0);
  fillchar(d,sizeof(d),0); fillchar(g,sizeof(g),0);
  fillchar(h,sizeof(h),$7f); fillchar(dep,sizeof(dep),0);
  fillchar(f,sizeof(f),0); fillchar(tid,sizeof(tid),0);
  fillchar(id,sizeof(id),0);
  for i:=1 to n<<2 do
  begin
   t[i].min:=oo; t[i].max:=-oo; t[i].tag:=0;
  end;
  for i:=1 to n-1 do
  begin
   readln(a[i],b[i],c[i]);
   add(a[i],b[i],c[i]);
   add(b[i],a[i],c[i]);
  end;

  dfs(1);
  fillchar(flag,sizeof(flag),0);
  dfs2(1,1);
  for i:=1 to n-1 do
  begin
   if dep[a[i]]<dep[b[i]] then tmp:=b[i]
    else tmp:=a[i];
   d[i]:=tmp; g[tmp]:=i; h[tmp]:=c[i];
  end;
 // h[1]:=0; d[n]:=1; g[1]:=n;
  build(1,n,1);
  while true do
  begin
   readln(ch); x:=0; y:=0; k:=length(ch);
   if ch[1]='D' then break; s:=0; fuhao:=1;
   for i:=1 to k do
   begin
    if ch[i]=' ' then begin inc(s); continue; end;
    if (s=1)and(ch[i]<>' ') then x:=x*10+ord(ch[i])-ord('0');
    if (s=2)and(ch[i]<>' ') then
    begin
     if ch[i]='-' then begin fuhao:=-1; continue; end
      else y:=y*10+ord(ch[i])-ord('0');
    end;
   end;
   if ch[1]='C' then change(1,n,tid[d[x]],fuhao*y,1);
   if ch[1]='N' then ngt(x,y);
   if ch[1]='Q' then
   begin
    writeln(ask(x,y));
    //writeln;
   end;
  end;
 end;
 close(input);
 close(output);
end.