【POJ2778】DNA Sequence（AC自动机，DP）

题意：

生物课上我们学到，DNA序列中只有A, C, T和G四种片段。

经科学发现，DNA序列中，包含某些片段会产生不好的基因，如片段”ATC”是不好片段，则”AGATCC”, “CATCAA”, “ATCATC”都是不好的DNA序列，这些不好片段我们可以称为病毒片段。

现在已知m个病毒片段， 问长度为n的DNA序列，有多少种可能不包含病毒片段。答案可能很大，取模 100000。

【数据规模和约定】

 

0<=m<=10  病毒片段长度不超过10，只含A,T,C,G字母

 

1<=n<=2000000000

思路：AC自动机

因为fail[i]一定是i的一个前缀的后缀，fail[i]如果带病毒i必定带病毒

转移：

 {

    dp[0,1]:=1;

  for i:=1 to m do

  for eachedge(i,j)

  begin

   dp[i,j]:=dp[i,j]+dp[i-1,i];

  end;              }

用矩阵乘法优化

const mo=100000;
type arr=array[1..110,1..110]of int64;
var y,c,ans,d:arr;
    s:array[1..4]of char;
    map:array[1..10000,'A'..'Z']of longint;
    f,b,q:array[1..200000]of longint;
    m,n,i,j,k,t,sum,num:longint;
    ch:string;

procedure build;
var i,k,d:longint;
begin
 k:=1; d:=length(ch);
 for i:=1 to d do
 begin
  if map[k,ch[i]]=0 then begin inc(num); map[k,ch[i]]:=num; end;
  k:=map[k,ch[i]];
 end;
 b[k]:=1;
end;

procedure acauto;
var t,w,i,u,p,son:longint;
begin
 t:=0; w:=1; q[1]:=1;
 while t<w do
 begin
  inc(t); u:=q[t];
  for i:=1 to 4 do
   if map[u,s[i]]>0 then
   begin
    son:=map[u,s[i]];
    p:=f[u];
    if u=1 then f[son]:=1
     else f[son]:=map[p,s[i]];
    inc(w); q[w]:=son;
   end
    else
    begin
     p:=f[u];
     if u=1 then map[u,s[i]]:=1
      else map[u,s[i]]:=map[p,s[i]];
    end;
 end;
end;

begin
 assign(input,'poj2778.in'); reset(input);
 assign(output,'poj2778.out'); rewrite(output);
 readln(m,n);
 num:=1;
 s[1]:='A'; s[2]:='C'; s[3]:='G'; s[4]:='T';
 for i:=1 to m do
 begin
  readln(ch);
  build;
 end;
 acauto;
 for i:=2 to num do
  if b[f[i]]=1 then b[i]:=1;

 for i:=1 to num do
  if b[i]=0 then
   for j:=1 to 4 do
    if b[map[i,s[j]]]=0 then inc(d[i,map[i,s[j]]]);

 t:=n;
 for i:=1 to num do ans[i,i]:=1;
 y:=d;
 while t>0 do
 begin
  if t and 1=1 then
  begin
   for i:=1 to num do
    for j:=1 to num do c[i,j]:=0;
   for i:=1 to num do
    for k:=1 to num do
    begin
     for j:=1 to num do c[i,k]:=c[i,k]+ans[i,j]*y[j,k];
     c[i,k]:=c[i,k] mod mo;
    end;
   for i:=1 to num do
    for j:=1 to num do ans[i,j]:=c[i,j];
  end;
  for i:=1 to num do
   for j:=1 to num do c[i,j]:=0;
  for i:=1 to num do
   for k:=1 to num do
   begin
    for j:=1 to num do c[i,k]:=c[i,k]+y[i,j]*y[j,k];
    c[i,k]:=c[i,k] mod mo;
   end;
  for i:=1 to num do
   for j:=1 to num do y[i,j]:=c[i,j];
  t:=t>>1;
 end;
 for i:=1 to num do sum:=(sum+ans[1,i]) mod mo;
 writeln(sum);


 close(input);
 close(output);
end.