【CF766D】Mahmoud and a Dictionary（并查集）

题意：有n个单词，给定m个关系，每个关系要么表示单词a与单词b相同，要么表示单词a与单词b相反。

并且“相同”与“相反”有性质：若a与b相同，b与c相同，则a与c相同（从而单词的相同关系是等价关系）；

若a与b相反，b与c相反，则a与c相同。按顺序判断这m个关系是否可以成立，若可以成立，则加上这个关系，否则忽略。

再给定q个询问，每个询问 查询单词a与单词b的关系（相同、相反或未知）。

n,m,q<=10^5

思路：并查集

设与i相反的单词集合中的代表为fan[i]，则x与y相同的条件是：find(fan[x])<>find(y)，合并(find(x),find(y))，(find(fan[x]),find(fan[y]))

不同：find(x)<>find(y)，合并时类似

询问类似

var a:array[1..110000]of string;
    fa,fan:array[1..200000]of longint;
    n,m,k,i,x,y,s,que,j,t1,t2,x1,y1,x2,y2:longint;
    tmp,mid,t,ch:ansistring;

procedure swap(var x,y:string);
begin
 t:=x; x:=y; y:=t;
end;

procedure qsort(l,r:longint);
var i,j,t:longint;
begin
 i:=l; j:=r; mid:=a[(l+r)>>1];
 repeat
  while mid>a[i] do inc(i);
  while mid<a[j] do dec(j);
  if i<=j then
  begin
   swap(a[i],a[j]);
   inc(i); dec(j);
  end;
 until i>j;
 if l<j then qsort(l,j);
 if i<r then qsort(i,r);
end;

function hash(x:string):longint;
var l,r,mid:longint;
begin
 l:=1; r:=n;
 while l<=r do
 begin
  mid:=(l+r)>>1;
  if a[mid]=x then exit(mid)
   else if a[mid]<x then l:=mid+1
    else r:=mid-1;
 end;
end;

function find(k:longint):longint;
begin
 if k=0 then exit(0);
 if fa[k]<>k then fa[k]:=find(fa[k]);
 exit(fa[k]);
end;

procedure union(x,y:longint);
var p,q:longint;
begin
 if (x=0)or(y=0) then exit;
 p:=find(x); q:=find(y);
 if p<>q then fa[p]:=q;
end;

begin
// assign(input,'cf766d.in'); reset(input);
 //assign(output,'cf766d.out'); rewrite(output);
 readln(n,m,que);
 readln(ch);
 k:=length(ch);
 s:=0;
 for j:=1 to k do
 begin
  if ch[j]=' ' then begin inc(s); a[s]:=tmp; tmp:=''; continue; end;
   tmp:=tmp+ch[j];
 end;
 inc(s); a[s]:=tmp;

 qsort(1,n);
 for i:=1 to n do
 begin
  fan[i]:=0; fa[i]:=i;
 end;
 for i:=1 to m do
 begin
  readln(ch); tmp:=''; s:=0;
  k:=length(ch);
  for j:=2 to k do
  begin
   if ch[j]=' ' then
   begin
    inc(s);
    if s=2 then x:=hash(tmp);
    tmp:='';
    continue;
   end;
   if (ch[j]>='a')and(ch[j]<='z') then tmp:=tmp+ch[j];
  end;
  y:=hash(tmp);
  x1:=find(x); y1:=find(y);
  x2:=find(fan[x1]); y2:=find(fan[y1]);
  case ch[1] of
   '1':
   begin
    if x2=y1 then writeln('NO')
     else
     begin
      writeln('YES');
      union(x1,y1);
      union(x2,y2);
      if y2=0 then fan[y1]:=x2;
     end;
   end;
   '2':
   begin
    if x1=y1 then writeln('NO')
     else
     begin
      writeln('YES');
      if x2>0 then union(y1,x2)
       else fan[x1]:=y1;
      if y2>0 then union(x1,y2)
       else fan[y1]:=x1;
     end;
   end;
  end;
 end;
 for i:=1 to que do
 begin
  readln(ch); tmp:=''; s:=0;
  k:=length(ch);
  for j:=1 to k do
  begin
   if ch[j]=' ' then
   begin
    inc(s);
    if s=1 then x:=hash(tmp);
    tmp:='';
    continue;
   end;
   if (ch[j]>='a')and(ch[j]<='z') then tmp:=tmp+ch[j];
  end;
  y:=hash(tmp);
  x1:=find(x); y1:=find(y);
  x2:=find(fan[x1]); y2:=find(fan[y1]);
  if x1=y1 then writeln(1)
   else if (x1=y2)or(x2=y1) then writeln(2)
    else writeln(3);
 end;
 //close(input);
 //close(output);
end.