【BZOJ1717&POJ3261】Milk Patterns（后缀数组，二分）

题意：求字符串的可重叠的k次最长重复子串

n<=20000 a[i]<=1000000

思路：后缀数组+二分答案x，根据height分组，每组之间的height>=x

因为可以重叠，所以只要判断是否有一组的height个数>=k即可

var sa,rank,x,y,a,wc,wd,height:array[0..1100000]of longint;
    n,m,i,l,r,mid,last,k1:longint;
 
procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;
 
function cmp(a,b,l:longint):boolean;
begin
 exit((y[a]=y[b])and(y[a+l]=y[b+l]));
end;
 
procedure getsa(n:longint);
var i,j,p:longint;
begin
 for i:=0 to n-1 do
 begin
  x[i]:=a[i];
  inc(wc[a[i]]);
 end;
 for i:=1 to m-1 do wc[i]:=wc[i-1]+wc[i];
 for i:=n-1 downto 0 do
 begin
  dec(wc[x[i]]);
  sa[wc[x[i]]]:=i;
 end;
 j:=1; p:=1;
 while p<n do
 begin
  p:=0;
  for i:=n-j to n-1 do
  begin
   y[p]:=i; inc(p);
  end;
  for i:=0 to n-1 do
   if sa[i]>=j then begin y[p]:=sa[i]-j; inc(p); end;
  for i:=0 to n-1 do wd[i]:=x[y[i]];
  for i:=0 to m-1 do wc[i]:=0;
  for i:=0 to n-1 do inc(wc[wd[i]]);
  for i:=1 to m-1 do wc[i]:=wc[i-1]+wc[i];
  for i:=n-1 downto 0 do
  begin
   dec(wc[wd[i]]);
   sa[wc[wd[i]]]:=y[i];
  end;
  for i:=0 to n do swap(x[i],y[i]);
  p:=1; x[sa[0]]:=0;
  for i:=1 to n-1 do
   if cmp(sa[i-1],sa[i],j) then x[sa[i]]:=p-1
    else begin x[sa[i]]:=p; inc(p); end;
  j:=j*2;
  m:=p;
 end;
end;
 
procedure getheight(n:longint);
var i,k,j:longint;
begin
 for i:=1 to n do rank[sa[i]]:=i;
 k:=0;
 for i:=0 to n-1 do
 begin
  if k>0 then dec(k);
  j:=sa[rank[i]-1];
  while a[i+k]=a[j+k] do inc(k);
  height[rank[i]]:=k;
 end;
end;
 
function isok(x:longint):boolean;
var s,i:longint;
begin
 s:=1;
 for i:=1 to n do
 begin
  if height[i]<x then
  begin
   if s>=k1 then exit(true);
   s:=1;
  end
   else inc(s);
 end;
 if s>=k1 then exit(true);
 exit(false);
end;
 
begin
 
 while not eof do
 begin
  fillchar(a,sizeof(a),0);
  fillchar(sa,sizeof(sa),0);
  fillchar(rank,sizeof(rank),0);
  fillchar(x,sizeof(x),0);
  fillchar(y,sizeof(y),0);
  fillchar(height,sizeof(height),0);
  fillchar(wc,sizeof(wc),0);
  fillchar(wd,sizeof(wd),0);
  readln(n,k1);
  if n=0 then break;
  for i:=0 to n-1 do
  begin
   read(a[i]);
   inc(a[i]);
  end;
  a[n]:=0; m:=1000001;
  getsa(n+1);
  getheight(n);
  l:=1; r:=n; last:=0;
  while l<=r do
  begin
   mid:=(l+r)>>1;
   if isok(mid) then begin last:=mid; l:=mid+1; end
    else r:=mid-1;
  end;
  writeln(last);
 // for i:=0 to n do writeln(height[i]);
 end;
 
 
 
end.