【Ural1297】Palindrome（后缀数组）

题意：求一个字符串的最长回文子串

n<=1000

思路：这是一道论文题

需要注意的细节：

1.奇偶分类

2.中间的分割符与最后的附加字母都是最小值，但两者不能相同，否则height可能会出现问题

答案即为min(height[rank[x]+1]...height[rank[y]])

var f:array[0..3000,0..11]of longint;
    x,y,sa,rank,height,a,wc,wd:array[0..3000]of longint;
    ch:ansistring;
    n,m,i,k,max,tmp,t,j:longint;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;

function cmp(a,b,l:longint):boolean;
begin
 exit((y[a]=y[b])and(y[a+l]=y[b+l]));
end;

procedure getsa(n:longint);
var i,j,p:longint;
begin
 for i:=0 to n-1 do
 begin
  x[i]:=a[i];
  inc(wc[a[i]]);
 end;
 for i:=1 to m-1 do wc[i]:=wc[i-1]+wc[i];
 for i:=n-1 downto 0 do
 begin
  dec(wc[x[i]]);
  sa[wc[x[i]]]:=i;
 end;
 j:=1; p:=1;
 while p<n do
 begin
  p:=0;
  for i:=n-j to n-1 do
  begin
   y[p]:=i; inc(p);
  end;
  for i:=0 to n-1 do
   if sa[i]>=j then begin y[p]:=sa[i]-j; inc(p); end;
  for i:=0 to n-1 do wd[i]:=x[y[i]];
  for i:=0 to m-1 do wc[i]:=0;
  for i:=0 to n-1 do inc(wc[wd[i]]);
  for i:=1 to m-1 do wc[i]:=wc[i-1]+wc[i];
  for i:=n-1 downto 0 do
  begin
   dec(wc[wd[i]]);
   sa[wc[wd[i]]]:=y[i];
  end;
  for i:=0 to n do swap(x[i],y[i]);
  p:=1; x[sa[0]]:=0;
  for i:=1 to n-1 do
   if cmp(sa[i-1],sa[i],j) then x[sa[i]]:=p-1
    else begin x[sa[i]]:=p; inc(p); end;
  j:=j*2;
  m:=p;
 end;
end;

procedure getheight(n:longint);
var i,j,k:longint;
begin
 k:=0;
 for i:=1 to n do rank[sa[i]]:=i;
 for i:=0 to n-1 do
 begin
  if k>0 then dec(k);
  j:=sa[rank[i]-1];
  while a[i+k]=a[j+k] do inc(k);
  height[rank[i]]:=k;
 end;
end;

function query(x,y:longint):longint;
var len,l:longint;
begin
 len:=y-x+1; l:=trunc(ln(len)/ln(2));
 exit(min(f[x,l],f[y-(1<<l)+1,l]));
end;

function lcp(x,y:longint):longint;
var i,j:longint;
begin
 //inc(x); inc(y);
 i:=rank[x]; j:=rank[y];
 if i>j then swap(i,j);
 inc(i);
 exit(query(i,j));
end;

procedure init;
begin
 fillchar(a,sizeof(a),0);
 fillchar(height,sizeof(height),0);
 fillchar(sa,sizeof(sa),0);
 fillchar(rank,sizeof(rank),0);
 fillchar(f,sizeof(f),0);
 fillchar(x,sizeof(x),0);
 fillchar(y,sizeof(y),0);
 fillchar(wc,sizeof(wc),0);
 fillchar(wd,sizeof(wd),0);
end;

begin
 assign(input,'ural1297.in'); reset(input);
 assign(output,'ural1297.out'); rewrite(output);
 while not eof do
 begin
  init;
  readln(ch);
  n:=length(ch);
  if n=0 then break;
  for i:=0 to n-1 do a[i]:=ord(ch[i+1]);
  a[n]:=1; m:=300;
  for i:=n+1 to 2*n do a[i]:=ord(ch[n-(i-n)+1]);
  a[n*2+1]:=0;
  getsa(n*2+2);
  getheight(n*2+1);
  m:=n*2+2;
  t:=trunc(ln(m)/ln(2));
  for i:=2 to m do f[i,0]:=height[i];
  for i:=1 to t do
   for j:=2 to m do
    if j+(1<<(i-1))<=m then f[j,i]:=min(f[j,i-1],f[j+(1<<(i-1)),i-1]);
  max:=0; k:=0;
  for i:=0 to n-1 do
  begin
   tmp:=lcp(i,2*n-i)*2-1;
   if tmp>max then
   begin
    max:=tmp;
    k:=i;
    end;
   if i>0 then
   begin
    tmp:=lcp(i,n*2-i+1)*2;
    if tmp>max then
    begin
     max:=tmp;
     k:=i;
    end;
   end;
  end;
  if max mod 2=1 then
   for j:=k-max div 2+1 to k+max div 2+1 do write(ch[j])
    else
     for j:=k-max div 2+1 to k+max div 2 do write(ch[j]);
  writeln;
 // for i:=2 to n*2+2 do writeln(height[i]);
 // for i:=1 to n*2+2 do writeln(rank[i]);
 // writeln;
 end;



 close(input);
 close(output);
end.