【SGU194&ZOJ2314】Reactor Cooling（有上下界的网络流）

题意：

给n个点，及m根pipe，每根pipe用来流躺液体的，单向的，每时每刻每根pipe流进来的物质要等于流出去的物质，要使得m条pipe组成一个循环体，里面流躺物质。

并且满足每根pipe一定的流量限制，范围为[Li,Ri].即要满足每时刻流进来的不能超过Ri(最大流问题)，同时最小不能低于Li。

n<=200

思路：

From HZWER

上界用ci表示，下界用bi表示。

下界是必须流满的，那么对于每一条边，去掉下界后，其自由流为ci– bi。

主要思想：每一个点流进来的流=流出去的流

对于每一个点i，令

Mi= sum(i点所有流进来的下界流)– sum(i点所有流出去的下界流)

如果Mi大于0，代表此点必须还要流出去Mi的自由流，那么我们从源点连一条Mi的边到该点。

如果Mi小于0，代表此点必须还要流进来Mi的自由流，那么我们从该点连一条Mi的边到汇点。

如果求S->T的最大流，看是否满流(S的相邻边都流满)。

满流则有解，否则无解。

以下是我的理解，用来说明算法的正确性：

首先不能根据给定的条件直接建图，因为不满足流量平衡

于是我们建立一些从源点连出与连入汇点的辅助边使平衡成立

但最终方案如果还是需要辅助边的话就说明无法调整原来的流量使平衡成立

所以只需要判断源点（我觉得汇点也应该判断，但只判源点也能过）相连的边上如果还有流量就无法构造出一组可行解

var head,vet,next,len,fan,a:array[1..210000]of longint;
    gap:array[0..500]of longint;
    dis,sum:array[1..500]of longint;
    n,m,i,j,x,y,z,tot,source,src,s,cas,v:longint;

procedure add(a,b,c:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 len[tot]:=c;
 head[a]:=tot;

 inc(tot);
 next[tot]:=head[b];
 vet[tot]:=a;
 len[tot]:=0;
 head[b]:=tot;
end;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

function dfs(u,aug:longint):longint;
var e,v,t,val,flow:longint;
begin
 if u=src then exit(aug);
 e:=head[u]; flow:=0; val:=s-1;
 while e<>0 do
 begin
  v:=vet[e];
  if len[e]>0 then
  begin
   if dis[u]=dis[v]+1 then
   begin
    t:=dfs(v,min(aug-flow,len[e]));
    len[e]:=len[e]-t;
    len[fan[e]]:=len[fan[e]]+t;
    flow:=flow+t;
    if dis[source]>=s then exit(flow);
    if aug=flow then break;
   end;
   val:=min(val,dis[v]);
  end;
  e:=next[e];
 end;
 if flow=0 then
 begin
  dec(gap[dis[u]]);
  if gap[dis[u]]=0 then dis[source]:=s;
  dis[u]:=val+1;
  inc(gap[dis[u]]);
 end;
 exit(flow);
end;

function maxflow:longint;
var ans:longint;
begin
 fillchar(gap,sizeof(gap),0);
 fillchar(dis,sizeof(dis),0);
 gap[0]:=s; ans:=0;
 while dis[source]<s do ans:=ans+dfs(source,maxlongint);
 exit(ans);
end;

function isok:boolean;
var u,e:longint;
begin
 u:=source; e:=head[u];
 while e<>0 do
 begin
  if len[e]>0 then exit(false);
  e:=next[e];
 end;
 exit(true);
end;

begin
 assign(input,'zoj2314.in'); reset(input);
 assign(output,'zoj2314.out'); rewrite(output);
 readln(cas);
 for i:=1 to 210000 do
  if i and 1=1 then fan[i]:=i+1
   else fan[i]:=i-1;
 for v:=1 to cas do
 begin
  for i:=1 to s do head[i]:=0;
  for i:=1 to n do sum[i]:=0;
  s:=0; tot:=0;
  read(n,m);
  for i:=1 to m do
  begin
   read(x,y,a[i],z);
   sum[y]:=sum[y]+a[i];
   sum[x]:=sum[x]-a[i];
   add(x,y,z-a[i]);
  end;
  source:=n+1; src:=n+2; s:=n+2;
  for i:=1 to n do
   if sum[i]<0 then add(i,src,-sum[i])
    else add(source,i,sum[i]);
  source:=n+1; src:=n+2; s:=n+2;
  maxflow;
  if isok then
  begin
   writeln('YES');
   for i:=1 to m do writeln(a[i]+len[i<<1]);
  end
   else writeln('NO');
  writeln;
 end;
 close(input);
 close(output);
end.