【HDOJ5714】拍照（线性扫描）

题意：小明在旅游的路上看到了一条美丽的河，河上有许多船只，有的船只向左航行，有的船只向右航行。小明希望拍下这一美丽的风景，并且把尽可能多的船只都完整地拍到一张照片中。

小明位于河的边上，并且可以在河边的任意位置进行拍照，照相机的视野恰好为90度角，只能以垂直于河边的方向进行拍照。河上的船只全都可看作是平行于河边的一条线段，跟河边的距离各不相同，有的正在向左移动，有的正在向右移动，但移动速度恰好都是一样的。小明可以等待恰当的时间让尽量多的船只都走进照相机的视野里，你不需要考虑船只之间会互相遮挡视野的情况。

下面T组数据，对于每组数据：
第一行是一个数n(1≤n≤104)，表示船只的数量。
接下来n行，每行四个整数
x,y,z,d(−10^6≤x<y≤10^6,1≤z≤104)，表示船只的左端点位置、右端点位置、距离河边的距离，以及航行的方向。d为−1表示向左航行，1表示向右航行。

思路：首先画图

发现船[x,y,z]只有在[y-z,x+z]的区域内能看到

然后因为速度一样，则向同一方向的船只的相对位置是一样的，可以把它们看成线段

正着做一次前缀和，反着做一次，求两个前（后）缀和之和的最大值即可

哈希新姿势

var a,b,c,d,f1,f2,g1,g2,h:array[1..30000]of longint;
    hash:array[-1500000..1500000]of longint;
    cas,v,n,m,i,tmp,ans,s1,s2,n1,up,x1,y1,z1,d1:longint;

procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;

function max(x,y:longint):longint;
begin
 if x>y then exit(x);
 exit(y);
end;

procedure qsort(l,r:longint);
var i,j,mid:longint;
begin
 i:=l; j:=r; mid:=h[(l+r)>>1];
 repeat
  while mid>h[i] do inc(i);
  while mid<h[j] do dec(j);
  if i<=j then
  begin
   swap(h[i],h[j]);
   inc(i); dec(j);
  end;
 until i>j;
 if l<j then qsort(l,j);
 if i<r then qsort(i,r);
end;

begin
 assign(input,'hdoj5714.in'); reset(input);
 assign(output,'hdoj5714.out'); rewrite(output);
 readln(cas);
 for v:=1 to cas do
 begin
  readln(n1);
  up:=0; n:=0; m:=0;
  for i:=1 to n1 do
  begin
   readln(x1,y1,z1,d1);
   if y1-z1<=x1+z1 then
   begin
    inc(n); a[n]:=y1-z1; b[n]:=x1+z1; d[n]:=d1;
    inc(m); h[m]:=y1-z1;
    inc(m); h[m]:=x1+z1;
   end;
  end;
  if m>0 then qsort(1,m);
  for i:=1 to m do
   if hash[h[i]]=0 then
   begin
    inc(up); hash[h[i]]:=up;
   end;
  fillchar(f1,sizeof(f1),0);
  fillchar(f2,sizeof(f2),0);
  fillchar(g1,sizeof(g1),0);
  fillchar(g2,sizeof(g2),0);
  for i:=1 to n do
   if d[i]=1 then
   begin
    inc(f1[hash[a[i]]]);
    dec(g1[hash[b[i]]]);
   end
    else
    begin
     inc(f2[hash[a[i]]]);
     dec(g2[hash[b[i]]]);
    end;
  s1:=0; s2:=0; ans:=0; tmp:=0;
  for i:=1 to up do
  begin
   s1:=s1+f1[i];
   tmp:=max(tmp,s1);
   s1:=s1+g1[i];
   s2:=s2+f2[i];
   ans:=max(ans,tmp+s2);
   s2:=s2+g2[i];
  end;
  writeln('Case #',v,':');
  writeln(ans);
  for i:=1 to m do hash[h[i]]:=0;
 end;

 close(input);
 close(output);
end.