pku 1182 食物链

种类并查集的经典题目，和NOIP2010里的关押罪犯一个类型，0，1，2表示三个种类，在合并时用类似向量的方法去导公式，其他的模拟操作即可。

program pku1182(input,output);
var
   father,r               : array[0..50000] of longint;
   i,n,x,y,answer,k,t : longint;  
function find(i               : longint):longint;
var
   temp:longint;
begin
   if father[i]=i then
      exit(i);
   temp:=father[i];
   father[i]:=find(father[i]);
   r[i]:=(r[temp]+r[i]) mod 3;
   exit(father[i]);
end;
procedure union(x,y,h:longint);
var
   a,b:longint;
begin
   a:=find(x);
   b:=find(y);
   father[a]:=b;
   r[a]:=(r[y]+h-r[x]+3) mod 3;
end;
begin
   answer:=0;
   readln(n,k);
   for i:=1 to n do
      father[i]:=i;
   for i:=1 to k do
   begin
      readln(t,x,y);
      if (x>n)or(y>n) then
      begin
     inc(answer);
     continue;
      end;
      case t of
    1:if find(x)=find(y) then
      begin
         if r[x]<>r[y] then
        inc(answer)
      end
      else
         union(x,y,0);
    2:begin
         if x=y then
         begin
        inc(answer);
        continue;
         end;
         if find(x)=find(y) then
         begin
        if r[x]<>(r[y]+1) mod 3 then
           inc(answer)
         end
         else
        union(x,y,1);
      end;
      end;
   end;
   writeln(answer);
end.