pku3264 Balanced Lineup

求区间最值之差，需要Qlogn的算法，可以用线段树或者ST。

线段树1750ms

program pku3264_line_tree(input,output);
type
   node    = record
         left,right,x,y,minx,maxx : longint;
      end;
var
   tree    : array[0..500000] of node;
   n,q    : longint;
   a    : array[0..200000] of longint;
   tot    : longint;
function min(aa,bb :longint ):longint;
begin
   if aa<bb then
      exit(aa);
   exit(bb);
end; { min }
function max(aa,bb :longint ):longint;
begin
   if aa>bb then
      exit(aa);
   exit(bb);
end; { max }
procedure build(xx,yy: longint );
var
   mid,now : longint;
begin
   inc(tot);
   tree[tot].x:=xx;
   tree[tot].y:=yy;
   if xx=yy then
   begin
      tree[tot].minx:=a[xx];
      tree[tot].maxx:=a[xx];
      exit;
   end;
   now:=tot;
   mid:=(xx+yy)>>1;
   tree[now].left:=tot+1;
   build(xx,mid);
   tree[now].right:=tot+1;
   build(mid+1,yy);
   tree[now].minx:=min(tree[tree[now].left].minx,tree[tree[now].right].minx);
   tree[now].maxx:=max(tree[tree[now].left].maxx,tree[tree[now].right].maxx);
end; { build }
procedure init;
var
   i : longint;
begin
   readln(n,q);
   for i:=1 to n do
      readln(a[i]);
   build(1,n);
end; { init }
function getmax(now,xx,yy :longint ):longint;
var
   mid : longint;
begin
   if (tree[now].x=xx)and(tree[now].y=yy) then
      exit(tree[now].maxx);
   mid:=(tree[now].x+tree[now].y)>>1;
   if yy<=mid then
      exit(getmax(tree[now].left,xx,yy))
   else
      if xx>mid then
     exit(getmax(tree[now].right,xx,yy))
      else
     exit(max(getmax(tree[now].left,xx,mid),getmax(tree[now].right,mid+1,yy)));
end; { getmax }
function getmin(now,xx,yy :longint ):longint;
var
   mid : longint;
begin
   if (tree[now].x=xx)and(tree[now].y=yy) then
      exit(tree[now].minx);
   mid:=(tree[now].x+tree[now].y)>>1;
   if yy<=mid then
      exit(getmin(tree[now].left,xx,yy))
   else
      if xx>mid then
     exit(getmin(tree[now].right,xx,yy))
      else
     exit(min(getmin(tree[now].left,xx,mid),getmin(tree[now].right,mid+1,yy)));
end; { getmin }
procedure solve();
var
   i,xx,yy : longint;
begin
   for i:=1 to q do
   begin
      readln(xx,yy);
      writeln(getmax(1,xx,yy)-getmin(1,xx,yy));
   end;
end; { solve }
begin
   init;
   solve;
end.

ST算法1204ms

program pku3264(input,output);
var
   f,g : array[0..200001,0..18] of longint;
   n,q : longint;
procedure init;
var
   i : longint;
begin
   readln(n,q);
   for i:=1 to n do
   begin
      readln(f[i,0]);
      g[i,0]:=f[i,0];
   end;
end; { init }
function min(aa,bb :longint ):longint;
begin
   if aa<bb then
      exit(aa);
   exit(bb);
end; { min }
function max(aa,bb :longint ):longint;
begin
   if aa>bb then
      exit(aa);
   exit(bb);
end; { max }
procedure main;
var
   i,j : longint;
begin
   for j:=1 to trunc(ln(n)/ln(2)) do
      for i:=1 to n do
     if i+1<<(j-1)>n then
        break
     else
     begin
        f[i,j]:=min(f[i,j-1],f[i+1<<(j-1),j-1]);
        g[i,j]:=max(g[i,j-1],g[i+1<<(j-1),j-1]);
     end;
end; { main }
procedure solve();
var
   i,x,y,t : longint;
begin
   for i:=1 to q do
   begin
      readln(x,y);
      t:=trunc(ln(y-x+1)/ln(2));
      writeln(max(g[x,t],g[y-1<<t+1,t])-min(f[x,t],f[y-1<<t+1,t]));
   end;
end; { solve }
begin
   init;
   main;
   solve;
end.

还是ST简洁啊，DP就是NB！