NOIP2003 传染病控制

一道答题解法一定细节解法并不怎么确定的题目，总体上就是搜索了。在每层当前可被感染的人中，只能选一个人，就先DFS建树，统计每一层的人，保存在一个表里，再进行搜索，一个人被控制后，就用递归把他的儿子全部赋值成不能染病，并在可染病人数中减去该子树大小，取最小值即可。

统计官方上都说要剪枝，但是我的程序最大点0.2S。

 program noip2003t4(input,output);
 type
    node=^link;
    link=record
        goal:longint;
        next:node;
    end;
var
    l,tree:array[0..401] of node;
    nodes:array[0..400,0..400] of longint;
    answer:longint;
    n,p,sum,maxdepth:longint;
    can,v:array[0..400] of boolean;
procedure add(xx,yy:longint);
var
    tt:node;
begin
    new(tt);
    tt^.next:=l[xx];
    tt^.goal:=yy;
    l[xx]:=tt;
end;{ add }
procedure add_tree(xx,yy:longint);
var
    tt:node;
begin
    new(tt);
    tt^.goal:=yy;
    tt^.next:=tree[xx];
    tree[xx]:=tt;
end;{ add_tree }
procedure init;
var
    i,xx,yy:longint;
begin
    readln(n,p);
    for i:=1 to n do
    begin
        l[i]:=nil;
        tree[i]:=nil;
    end;
    for i:=1 to p do
    begin
        read(xx,yy);
        add(xx,yy);
        add(yy,xx);
    end;
    fillchar(nodes,sizeof(nodes),0);
end;{ init }
procedure build(now:longint);
var
    t:node;
begin
    v[now]:=true;
    t:=l[now];
    while t<>nil do
    begin
        if not v[t^.goal] then
        begin
            add_tree(now,t^.goal);
            build(t^.goal);
        end;
        t:=t^.next;
    end;
end;{ build }
procedure calc(now,depth:longint);
var
    t:node;
begin
    if depth>maxdepth then
        maxdepth:=depth;
    inc(nodes[depth,0]);
    nodes[depth,nodes[depth,0]]:=now;
    t:=tree[now];
    while t<>nil do
    begin
        calc(t^.goal,depth+1);
        t:=t^.next;
    end;
end;{ calc }
function change(now:longint;flag:boolean):longint;
var
    t:node;
begin
    change:=1;
    can[now]:=flag;
    t:=tree[now];
    while t<>nil do
    begin
        change:=change+change(t^.goal,flag);
        t:=t^.next;
    end;
end;{ change }
function check(now:longint):boolean;
var
    i:longint;
begin
    for i:=1 to nodes[now,0] do
        if can[nodes[now,i]] then
            exit(true);
    exit(false);
end;{ check }
procedure dfs(depth:longint);
var
    i:longint;
begin
    if depth=maxdepth+1 then
    begin
        if sum<answer then
            answer:=sum;
        exit;
    end;
    for i:=1 to nodes[depth,0] do
    if can[nodes[depth,i]] then
    begin
        dec(sum,change(nodes[depth,i],false));
        if not check(depth+1) then
        begin
            if sum<answer then
                answer:=sum;
        end
        else
            dfs(depth+1);
        inc(sum,change(nodes[depth,i],true));
    end;
end;{ dfs }
procedure main;
begin
    maxdepth:=0;
    fillchar(can,sizeof(can),true);
    fillchar(v,sizeof(v),false);
    answer:=maxlongint;
    build(1);
    calc(1,1);
    sum:=n;
    dfs(2);
    writeln(answer);
end;{ main }
begin
    assign(input,'Epidemic.in');reset(input);
    assign(output,'Epidemic.out');rewrite(output);
    init;
    main;
    close(input);
    close(output);
end.