NOI2001 炮兵阵地详解

【题目描述】
 
司令部的将军们打算在N*M的网格地图上部署他们的炮兵部队。一个N*M的地图由N行M列组成，地图的每一格可能是山地（用"H" 表示），也可能是平原（用"P"表示），如下图。在每一格平原地形上最多可以布置一支炮兵部队（山地上不能够部署炮兵部队）；一支炮兵部队在地图上的攻击范围如图中黑色区域所示：
                    

如果在地图中的灰色所标识的平原上部署一支炮兵部队，则图中的黑色的网格表示它能够攻击到的区域：沿横向左右各两格，沿纵向上下各两格。图上其它白色网格均攻击不到。从图上可见炮兵的攻击范围不受地形的影响。
现在，将军们规划如何部署炮兵部队，在防止误伤的前提下（保证任何两支炮兵部队之间不能互相攻击，即任何一支炮兵部队都不在其他支炮兵部队的攻击范围内），在整个地图区域内最多能够摆放多少我军的炮兵部队。
 

【输入文件】Input
 
第一行包含两个由空格分割开的正整数，分别表示N和M；
接下来的N行，每一行含有连续的M个字符('P'或者'H')，中间没有空格。按顺序表示地图中每一行的数据。N <= 100；M <= 10。
 

【输出文件】Output
 
仅一行，包含一个整数K，表示最多能摆放的炮兵部队的数量。
 

【输入样例】Sample Input
 
5 4
PHPP
PPHH
PPPP
PHPP
PHHP
 

【输出样例】Sample Output
 
6

【题目解析】

    对于一个位置，如果它部署了一支部队，那么会对它的前后左右的2格位置产生影响，如果以行作为状态，则不能单单由上一状态转移，那样的话不能保证在它的2格处不发生矛盾，而在这个题目中，以行做状态又很明显，所以在状态的转移时必须是上一行的状态和上上行的状态一起转移，如果用f[i,j,k]来表示在第i行时，取第j个状态（注意是第j个状态），i-1行取的是第k个状态，那么不难得出状态转移方程：

     f[i,j,k]=max{f[i,j,k],f[i-1,k,l]+ff[i,j]}

    解释一下这个方程i,j,k的含义如上述，l表示在第i-2行取第l个状态，ff[i,j]表示在第i行取第j个状态时在该行放置的多少支部队，由于第二行仅与第一行有关，所以要对第二行进行一下特殊处理，对于第二行，我们有

     f[2,j,k]=max{ff[2,j]+ff[1,k]};

     这样一来，对动态规划的模型基本处理就完成了，同时我们发现，在m=10时，每一行的状态有2^10种，显然时间和空间都不能承受，必须做出优化，仔细阅读题目，发现如果一个点部署了部队，则其前后两格范围内均不能再部署部队，而且在一个格子为H时，它根本不能部署部队，因此，在许多的状态中，有许多状态是自相矛盾的，根本不需要考虑，可以用某种预处理，把状态提取出来，仅仅储存有用的状态，在这里我的方法是用深度优先搜索预处理一下，try(x:longint)为处理某一行的第x个位置，如果这个位置部署部队，那么x+1,x+2这两个位置都不能放，直接try(x+3)即可，而如果这个地方是山地，就不能放，则try(x+1),即使是平原，也可以不去部署部队，因此还原后也要try(x+1)，预处理结束。

     对于状态的储存，为了简洁，用一个二进制数来表示，如当m=4时有一种状态为放，不放，不放，放，就用1代表放，0代表不放，这个二进制数为1001，转化为十进制数为9.这样状态的储存问题就迎刃而解了。

     接下来，判断状态的矛盾问题，这用到了位运算的知识，1001and0011=0001 这已经很明了了，判断两行间的状态是否矛盾，只需要用（状态1）and（状态2），如果结果是0，说明两个状态不矛盾。

program connon(input,output);
var g:array[1..100,1..100] of longint;
    ff:array[1..100,1..100] of longint;
    f:array[1..100,1..100,1..100] of longint;
    a:array[1..100,1..10] of char;
    d:array[1..100] of longint;
    i,j,k,l,maxn,m,n,tot,sum,ans:longint;
procedure init;
begin
  readln(n,m);
  for i:=1 to n do
  begin
   for j:=1 to m do
     ead(a[i,j]);
   readln;
  end;
  fillchar(f,sizeof(f),0);
end;
function max(x,y:longint):longint;
begin
  if x>y then
   exit(x)
  else
   exit(y);
end;
procedure dfs(x:longint);
begin
  if x>m then
  begin
    inc(tot);
    g[i,tot]:=sum;
    ff[i,tot]:=ans;
    d[i]:=tot;
    exit;
  end;
  if a[i,x]='P' then
  begin
    sum:=sum+1<<(x-1);
    inc(ans);
    dfs(x+3);
    sum:=sum-1<<(x-1);
    dec(ans);
  end;
  dfs(x+1);
end;
procedure make;
begin
  for i:=1 to d[2] do
   for j:=1 to d[1] do
   if  (g[1,j] and g[2,i]=0) then
     f[2,i,j]:=ff[2,i]+ff[1,j];
end;
procedure dp;
begin
  for i:=3 to n do
   for j:=1 to d[i] do
    for k:=1 to d[i-1] do
     for l:=1 to d[i-2] do
      if (g[i,j] and g[i-1,k]=0) then
       if (g[i,j] and g[i-2,l]=0) then
        if (g[i-1,k] and g[i-2,l]=0) then
         f[i,j,k]:=max(f[i,j,k],f[i-1,k,l]+ff[i,j]);
end;
procedure choose;
var i,j,k:longint;
begin
   maxn:=-(maxlongint>>1);
   for i:=1 to d[n] do
     for j:=1 to d[n-1] do
      if f[n,i,j]>maxn then
       maxn:=f[n,i,j];
end;
procedure print;
begin
  writeln(maxn);
end;
begin
  assign(input,'connon.in');reset(input);
  assign(output,'connon.out');rewrite(output);
  init;
  for i:=1 to n do
  begin
    tot:=0;
    sum:=0;
    ans:=0;
    dfs(1);
  end;
  make;
  dp;
  choose;
  print;
  close(input);
  close(output);
end.