Flare3D游戏特效教程：火拳阿宝

截图预览：

网页预览：http://eko.kooteam.com/flare3d/abao/

一 思路

我们在玩游戏的时候，经常能看到一些粒子特效被绑定在武器上，装备上。其实就是将粒子定位在某个对象上。在这篇教程中，我们把火焰粒子绑定在阿宝的两个手掌的骨骼上。

二 准备

现在我们需要一个火焰粒子特效和一个阿宝的模型。

粒子特效我直接拿了yblunan的东西，地址如下：火焰粒子

阿宝的模型在最后附件中提供，值得注意的是，模型中我将左右手掌需要绑定的骨骼命名为fire，fire2。

接下来先看看完整代码，然后逐步讲解。

三 完整代码

package
{
    import base.Base;

    import components.BoneController;

    import flare.basic.Scene3D;
    import flare.basic.Viewer3D;
    import flare.core.Camera3D;
    import flare.core.Mesh3D;
    import flare.core.ParticleEmiter3D;
    import flare.core.Pivot3D;
    import flare.core.Texture3D;
    import flare.materials.ParticleMaterial3D;
    import flare.materials.filters.ColorParticleFilter;
    import flare.materials.filters.TextureFilter;

    import flash.display.Bitmap;
    import flash.events.Event;

    [SWF(width=800,height=600)]
    public class TheBao extends Base
    {
        [Embed(source="fire.png")]
        private var Fire:Class;

        [Embed(source="abao.f3d",mimeType="application/octet-stream")]
        private var ABao:Class;
        private var scene:Scene3D;
        private var bao:Pivot3D;
        public function TheBao(info:String="粒子绑定骨骼")
        {
            super(info);
            scene=new Viewer3D(this);
            scene.camera=new Camera3D();
            scene.camera.z=-250;
            scene.camera.y=100;
            //scene.frameRate=10;
            scene.addEventListener(Scene3D.COMPLETE_EVENT,onCom);

            bao=scene.addChildFromFile(new ABao);

        }
        private function onCom(e:Event):void
        {

            var fire:Bitmap=new Fire();
            var pm:ParticleMaterial3D=new ParticleMaterial3D();
            pm.filters.push(new TextureFilter(new Texture3D(fire.bitmapData)));
            pm.filters.push(new ColorParticleFilter([0xffffff,0xffff00,0xff0000,0x000000],[1,.5,.2,0]));
            pm.build();

            var fireEmiter:ParticleEmiter3D=new ParticleEmiter3D("",pm,new FireParticle());
            fireEmiter.particlesLife=20;
            fireEmiter.emitParticlesPerFrame=50;
            fireEmiter.rotateX(90);
            fireEmiter.layer=10;

            var fireEmiter2:ParticleEmiter3D=new ParticleEmiter3D("",pm,new FireParticle());
            fireEmiter2.particlesLife=20;
            fireEmiter2.emitParticlesPerFrame=50;
            fireEmiter2.rotateX(90);
            fireEmiter2.layer=11;

            var baoMesh:Mesh3D=bao.getChildByName("bao") as Mesh3D;
            fireEmiter.addComponent(new BoneController(baoMesh,"fire"));
            fireEmiter2.addComponent(new BoneController(baoMesh,"fire2"));
            scene.addChild(fireEmiter);
            scene.addChild(fireEmiter2);
        }
    }
}

四 代码分析

首先，创建场景，设定摄像机位置，并加载阿宝的模型

super(info);
scene=new Viewer3D(this);
scene.camera=new Camera3D();
scene.camera.z=-250;
scene.camera.y=100;
scene.addEventListener(Scene3D.COMPLETE_EVENT,onCom);
bao=scene.addChildFromFile(new ABao);

其次，我们来创建火焰粒子

//创建火焰粒子的材质
var fire:Bitmap=new Fire();
var pm:ParticleMaterial3D=new ParticleMaterial3D();
pm.filters.push(new TextureFilter(new Texture3D(fire.bitmapData)));
pm.filters.push(new ColorParticleFilter([0xffffff,0xffff00,0xff0000,0x000000],[1,.5,.2,0]));
pm.build();

//实例化两个火焰粒子
var fireEmiter:ParticleEmiter3D=new ParticleEmiter3D("",pm,new FireParticle());
//粒子的生命，也就是过多久会消失
fireEmiter.particlesLife=20;
//每帧生成多少个粒子
fireEmiter.emitParticlesPerFrame=50;
//将粒子绕x轴旋转了90度，确保发射方向从掌心射出
fireEmiter.rotateX(90);
fireEmiter.layer=10;

var fireEmiter2:ParticleEmiter3D=new ParticleEmiter3D("",pm,new FireParticle());
fireEmiter2.particlesLife=20;
fireEmiter2.emitParticlesPerFrame=50;
fireEmiter2.rotateX(90);
fireEmiter2.layer=11;

再次 我们将火焰粒子绑定到骨骼上,这里用到官方提供的自定义骨骼控制类BoneController

var baoMesh:Mesh3D=bao.getChildByName("bao") as Mesh3D;
fireEmiter.addComponent(new BoneController(baoMesh,"fire"));
fireEmiter2.addComponent(new BoneController(baoMesh,"fire2"));
scene.addChild(fireEmiter);
scene.addChild(fireEmiter2);

五 所有资源打包放出

点击下载 abao