bzoj3196: Tyvj 1730 二逼平衡树

这题太经典了……树套树模板题……写着超级爽，思路流畅，最后卡了一会儿常就过去了……

我就是来粘个代码的……fhqtreap写着比较舒服

/**************************************************************
    Problem: 3196
    User: 1090900715
    Language: Pascal
    Result: Accepted
    Time:10812 ms
    Memory:60084 kb
****************************************************************/
 
{$S-}{$I-}{$V-}{$R-}
program j01;
uses math;
type xx=record l,r,size,w,f:longint; end;
const maxn=50086;
var t:array[0..60*maxn]of xx;
    root:array[0..4*maxn]of longint;
    a:array[0..maxn]of longint;
    n,m,tt,l,r,op,k,ps,i,mm:longint;
procedure update(const i:longint);inline;
begin
  if i=0 then exit;
  t[i].size:=t[t[i].l].size+t[t[i].r].size+1;
end;
function merge(x,y:longint):longint;
begin
  if (x=0)or(y=0) then exit(x+y);
  if t[x].f>t[y].f then
  begin
    t[x].r:=merge(t[x].r,y);update(x);exit(x);
  end else
  begin
    t[y].l:=merge(x,t[y].l);update(y);exit(y);
  end;
end;
procedure splite(i,x:longint;var k1,k2:longint);
begin
  if i=0 then
  begin
    k1:=0;k2:=0;exit;
  end;
  if t[i].w<x then
  begin
    k1:=i;splite(t[i].r,x,t[i].r,k2);
  end else
  begin
    k2:=i;splite(t[i].l,x,k1,t[i].l);
  end;
  update(i);
end;
function insert(i,k:longint):longint;
begin
  if i=0 then exit(k);
  if t[i].f>t[k].f then
  begin
    if t[i].w<t[k].w then t[i].r:=insert(t[i].r,k)
      else t[i].l:=insert(t[i].l,k);
    update(i);exit(i);
  end;
  splite(i,t[k].w,t[k].l,t[k].r);update(k);exit(k);
end;
function faskr(i,x:longint):longint;
var k1,k2:longint;
begin
  splite(root[i],x,k1,k2);
  faskr:=t[k1].size;root[i]:=merge(k1,k2);
end;
function cal(i,x:longint):longint;
var k1,k2:longint;
begin
  splite(root[i],x,k1,k2);cal:=t[k1].size;
  root[i]:=merge(k1,k2);
end;
 
function faskp(i,x:longint):longint;
var k,k1,k2:longint;
begin
  splite(root[i],x,k1,k2);if k1=0 then exit(0);
  k:=k1;while t[k].r<>0 do k:=t[k].r;
  root[i]:=merge(k1,k2);
  exit(t[k].w);
end;
function faskn(i,x:longint):longint;
var k,k1,k2:longint;
begin
  splite(root[i],x,k1,k2);if k2=0 then exit(mm);
  k:=k2;while t[k].l<>0 do k:=t[k].l;
  root[i]:=merge(k1,k2);
  exit(t[k].w);
end;
procedure add(i,l,r,ps,x:longint);
var mid:longint;
begin
  inc(tt);t[tt].f:=random(maxlongint);t[tt].w:=x;t[tt].size:=1;
  root[i]:=insert(root[i],tt);
  if l=r then exit;
  mid:=(l+r) div 2;
  if ps<=mid then add(i*2,l,mid,ps,x) else add(i*2+1,mid+1,r,ps,x);
end;
procedure des(i,l,r,ps,x:longint);
var mid,k1,k2,k3:longint;
begin
  splite(root[i],x,k1,k2);splite(k2,x+1,k2,k3);
  root[i]:=merge(merge(k1,t[k2].l),merge(t[k2].r,k3));
  if l=r then exit;
  mid:=(l+r) div 2;
  if ps<=mid then des(i*2,l,mid,ps,x) else des(i*2+1,mid+1,r,ps,x);
end;
function askrank(i,l,r,ll,rr,x:longint):longint;
var mid:longint;
begin
  if (ll<=l)and(r<=rr) then exit(faskr(i,x));
  mid:=(l+r)div 2;askrank:=0;
  if ll<=mid then askrank:=askrank+askrank(i*2,l,mid,ll,rr,x);
  if rr>=mid+1 then askrank:=askrank+askrank(i*2+1,mid+1,r,ll,rr,x);
end;
function calc(i,l,r,ll,rr,x:longint):longint;
var mid:longint;
begin
  if (ll<=l)and(r<=rr) then exit(cal(i,x));
  mid:=(l+r)div 2;calc:=0;
  if ll<=mid then calc:=calc+calc(i*2,l,mid,ll,rr,x);
  if rr>=mid+1 then calc:=calc+calc(i*2+1,mid+1,r,ll,rr,x);
end;
function askpre(i,l,r,ll,rr,x:longint):longint;
var mid:longint;
begin
  if (ll<=l)and(r<=rr) then exit(faskp(i,x));
  mid:=(l+r)div 2;askpre:=0;
  if ll<=mid then askpre:=max(askpre,askpre(i*2,l,mid,ll,rr,x));
  if rr>=mid+1 then askpre:=max(askpre,askpre(i*2+1,mid+1,r,ll,rr,x));
end;
function asknex(i,l,r,ll,rr,x:longint):longint;
var mid:longint;
begin
  if (ll<=l)and(r<=rr) then exit(faskn(i,x+1));
  mid:=(l+r)div 2;asknex:=mm;
  if ll<=mid then asknex:=min(asknex,asknex(i*2,l,mid,ll,rr,x));
  if rr>=mid+1 then asknex:=min(asknex,asknex(i*2+1,mid+1,r,ll,rr,x));
end;
function ask(const ll,rr,x:longint):longint;inline;
var l,r,mid,tmp:longint;
begin
  l:=0;r:=mm;
  while l<r do
  begin
    mid:=(l+r)div 2;tmp:=calc(1,1,n,ll,rr,mid+1);
    if tmp>x then r:=mid else l:=mid+1;
  end;
  exit(l);
end;
begin
  readln(n,m);
  tt:=0;randomize;mm:=0;
  for i:=1 to n do
  begin
    read(a[i]);add(1,1,n,i,a[i]);mm:=max(mm,a[i]);
  end;
  for i:=1 to m do
  begin
    read(op);
    if op=1 then
    begin
      readln(l,r,k);
      writeln(askrank(1,1,n,l,r,k)+1);
    end;
    if op=2 then
    begin
      readln(l,r,k);
      writeln(ask(l,r,k-1));
    end;
    if op=3 then
    begin
      readln(ps,k);
      des(1,1,n,ps,a[ps]);
      a[ps]:=k;mm:=max(mm,k);
      add(1,1,n,ps,a[ps]);
    end;
    if op=4 then
    begin
      readln(l,r,k);
      writeln(askpre(1,1,n,l,r,k));
    end;
    if op=5 then
    begin
      readln(l,r,k);
      writeln(asknex(1,1,n,l,r,k));
    end;
  end;
end.