bzoj3307: 雨天的尾巴

3307: 雨天的尾巴

Time Limit: 10 Sec  Memory Limit: 128 MB
Submit: 479  Solved: 214
[Submit][Status][Discuss]

Description

N个点，形成一个树状结构。有M次发放，每次选择两个点x,y
对于x到y的路径上（含x,y)每个点发一袋Z类型的物品。完成
所有发放后，每个点存放最多的是哪种物品。

Input

第一行数字N，M
接下来N-1行，每行两个数字a,b,表示a与b间有一条边
再接下来M行，每行三个数字x,y,z.如题

Output

输出有N行
每i行的数字表示第i个点存放最多的物品是哪一种，如果有
多种物品的数量一样，输出编号最小的。如果某个点没有物品
则输出0

题解

这题有点奥妙重重啊……我数组开大了不到十分之一就卡着内存过了

考虑每种颜色，我们可以树上差分，x,y处+1，xy的lca处-1，lca的father-1，然后子树和就是颜色在这个点的数量。然后我们用一个线段树来维护每个节点所有的颜色的值（这个用差分做）和他们的最大值，然后从底向上一路线段树合并上去就行了

program j01;
const maxn=100086;
type xx=record l,r,mx,id:longint; end;
     lsh=record id,w:longint; end;
var head:array[0..maxn]of longint;
    q,next:array[0..2*maxn]of longint;
    t:array[0..65*maxn]of xx;
    st:array[0..20,0..2*maxn]of longint;
    dep,fir,dfn,fa,root:array[0..maxn]of longint;
    tot,dfnt,tt,n,m,u,v,w,cnt,lc,p,i,mx:longint;
    op:array[0..maxn]of record u,v,w:longint;end;
    ls:array[0..maxn]of lsh;
    bin,ps:array[0..maxn]of longint;
    ans:array[0..maxn]of longint;

procedure swap(var a,b:longint);
var c:longint;
begin
  c:=a;a:=b;b:=c;
end;

procedure add(u,v:longint);
begin
  inc(tt);q[tt]:=v;next[tt]:=head[u];head[u]:=tt;
end;

procedure dfs(i,pre:longint);
var j:longint;
begin
  inc(tot);st[0,tot]:=i;fir[i]:=tot;
  inc(dfnt);dfn[dfnt]:=i;
  j:=head[i];
  while j>0 do
  begin
    if(q[j]<>pre)then
    begin
      dep[q[j]]:=dep[i]+1;fa[q[j]]:=i;
      dfs(q[j],i);
      inc(tot);st[0,tot]:=i;
    end;
    j:=next[j];
  end;
end;

function min_st(a,b:longint):longint;
begin
  if dep[a]<dep[b] then exit(a) else exit(b);
end;

procedure getst;
var i,j:longint;
begin
  bin[1]:=0;
  for i:=2 to tot do
    if i and(i-1)=0 then bin[i]:=bin[i-1]+1 else bin[i]:=bin[i-1];
  for i:=1 to bin[tot] do
    for j:=1 to tot+1-(1 shl i) do
      st[i,j]:=min_st(st[i-1,j],st[i-1,j+(1 shl(i-1))]);
end;

function lca(u,v:longint):longint;
var k:longint;
begin
  if u=v then exit(u);
  u:=fir[u];v:=fir[v];
  if u>v then swap(u,v);k:=bin[v-u];
  exit(min_st(st[k,u],st[k,v+1-(1 shl k)]));
end;

procedure update(i:longint);
begin
  if t[t[i].l].mx>=t[t[i].r].mx then
  begin
    t[i].mx:=t[t[i].l].mx;t[i].id:=t[t[i].l].id;
  end else
  begin
    t[i].mx:=t[t[i].r].mx;t[i].id:=t[t[i].r].id;
  end;
  if t[i].mx=0 then t[i].id:=0;
end;

procedure ins(var i:longint;l,r,ps,dd:longint);
var mid:longint;
begin
  if i=0 then
  begin
    inc(cnt);i:=cnt;
  end;
  if l=r then
  begin
    inc(t[i].mx,dd);t[i].id:=l;exit;
  end;
  mid:=(l+r)div 2;
  if ps<=mid then ins(t[i].l,l,mid,ps,dd) else ins(t[i].r,mid+1,r,ps,dd);
  update(i);
end;

function merge(x,y,l,r:longint):longint;
var mid:Longint;
begin
  if(x=0)or(y=0)then exit(x+y);
  if l=r then
  begin
    inc(t[x].mx,t[y].mx);t[x].id:=l;exit(x);
  end;
  mid:=(l+r)div 2;
  t[x].l:=merge(t[x].l,t[y].l,l,mid);
  t[x].r:=merge(t[x].r,t[y].r,mid+1,r);
  update(x);exit(x);
end;

procedure qsort(l,r:longint);
var i,j,x:longint;y:lsh;
begin
  i:=l;j:=r;x:=ls[(i+j)div 2].w;
  repeat
    while ls[i].w<x do inc(i);
    while x<ls[j].w do dec(j);
    if i<=j then
    begin
      y:=ls[i];ls[i]:=ls[j];ls[j]:=y;
      inc(i);dec(j);
    end;
  until i>j;
  if i<r then qsort(i,r);
  if l<j then qsort(l,j);
end;

procedure disc;
var i:longint;
begin
  qsort(1,m);
  op[ls[1].id].w:=1;mx:=1;
  ps[1]:=ls[1].w;
  for i:=2 to m do
  begin
    if ls[i].w<>ls[i-1].w then inc(mx);
    op[ls[i].id].w:=mx;
    ps[mx]:=ls[i].w;
  end;
end;

begin
  readln(n,m);
  fillchar(head,sizeof(head),0);tt:=0;
  for i:=1 to n-1 do
  begin
    readln(u,v);add(u,v);add(v,u);
  end;
  dfs(1,0);
  getst;
  for i:=1 to m do
  begin
    readln(op[i].u,op[i].v,op[i].w);
    ls[i].w:=op[i].w;ls[i].id:=i;
  end;
  disc;
  for i:=1 to m do
  begin
    u:=op[i].u;v:=op[i].v;w:=op[i].w;
    lc:=lca(u,v);
    ins(root[u],1,mx,w,1);
    ins(root[v],1,mx,w,1);
    ins(root[lc],1,mx,w,-1);
    if fa[lc]<>0 then ins(root[fa[lc]],1,mx,w,-1);
  end;
  for i:=n downto 1 do
  begin
    p:=dfn[i];
    ans[p]:=ps[t[root[p]].id];
    if fa[p]>0 then root[fa[p]]:=merge(root[fa[p]],root[p],1,mx);
  end;
  for i:=1 to n do writeln(ans[i]);
end.