bzoj2527

首先环可以变成链来处理，对于l>r的情况就是修改区间[1,r],[l,mx]
然后不难想到整体二分，二分答案k,然后算1~k场流星雨对国家的贡献
然后判定将国家划分变成子问题解决，没什么难的
终于不是tle，poi良心了一把

type way=record
       po,next:longint;
     end;
     que=record
       p,n:longint;
     end;
     an=record
       l,r,v:longint;
     end;
var a:array[0..300010] of an;
    qq,q:array[0..300010] of que;
    e:array[0..300010] of way;
    c:array[0..300010] of int64;
    p,ans,h:array[0..300010] of longint;
    v:array[0..300010] of boolean;
    tot,t,j,n,m,x,i:longint;
    s:int64;

function lowbit(x:longint):longint;
  begin
    exit(x and (-x));
  end;

procedure add(x,y:longint);
  begin
    e[i].po:=i;
    e[i].next:=p[x];
    p[x]:=i;
  end;

procedure ins(x:longint;w:int64);
  begin
    while x<=n do
    begin
      if not v[x] then  //清理标记
      begin
        inc(tot);
        h[tot]:=x;
        v[x]:=true;
      end;
      c[x]:=c[x]+w;
      x:=x+lowbit(x);
    end;
  end;

function ask(x:longint):int64;
  begin
    ask:=0;
    while x>0 do
    begin
      ask:=ask+c[x];
      x:=x-lowbit(x);
    end;
  end;

procedure work(f,t,l,r:longint);
  var mid,l1,l2:longint;
  begin
    if f>t then exit;
    if l>r then exit;
    mid:=(l+r) shr 1;
    tot:=0;
    for i:=l to mid do
      if a[i].l<=a[i].r then
      begin
        ins(a[i].l,a[i].v);
        ins(a[i].r+1,-a[i].v);
      end
      else begin
        ins(1,a[i].v);
        ins(a[i].r+1,-a[i].v);
        ins(a[i].l,a[i].v);
      end;

    l1:=f;
    l2:=t;
    for i:=f to t do
    begin
      j:=p[q[i].p];
      s:=0;
      while j<>0 do
      begin
        s:=s+ask(e[j].po);
        if s>=q[i].n then
        begin
          qq[l1]:=q[i];
          inc(l1);
          ans[q[i].p]:=mid;
          break;
        end;
        j:=e[j].next;
      end;
      if s<q[i].n then
      begin
        q[i].n:=q[i].n-s;  //对于还不够的国家，直接把这部分贡献减去即可，下次直接处理mid之后的流星雨的贡献
        qq[l2]:=q[i];
        dec(l2);
      end;
    end;
    for i:=1 to tot do
    begin
      c[h[i]]:=0;
      v[h[i]]:=false;
    end;
    for i:=f to t do
      q[i]:=qq[i];
    work(f,l1-1,l,mid-1);
    work(l2+1,t,mid+1,r);
  end;

begin
  readln(m,n);
  for i:=1 to n do
  begin
    read(x);
    add(x,i);
  end;
  for i:=1 to m do
  begin
    read(q[i].n);
    q[i].p:=i;
  end;
  readln(t);
  for i:=1 to t do
    readln(a[i].l,a[i].r,a[i].v);
  work(1,m,1,t);
  for i:=1 to m do
    if ans[i]=0 then writeln('NIE')
    else writeln(ans[i]);
end.