bzoj1176 2683

我的第一道cdq分治题
清明做了一下cdq分治的几道题，感觉这个东西实在是太厉害了
离线大法好！关于几个经典的非数据结构做法具体可以看xhr神犇2013年的论文
应用cdq分治的前提条件是不强制在线，修改操作互不影响。
什么是互相影响，比如在第i个数后面插入一个数，这就明显是会影响到后面的操作
在这个前提条件下，我们可以按照操作序列的时间线（先后）划分成两个规模缩小一半的子问题
显然后面的修改对前面无影响，而后半部分的修改对后半部分的询问、前半部分对前半部分的询问是子问题，可以递归解决
所以下面我们只要解决前半部分的所有修改操作对后半部分询问答案的贡献即可
注意这里其实就相当于给出初始值不断进行无修改询问
也就是我们通过分治（1个log的代价，根据主定理可知），干掉了动态修改
回到这题上来，由于矩阵很大，不能支持二维数据结构，并且满足前提条件，所以用cdq分治
之后就变成了给定矩阵上一些值，求子矩阵和这样一个无修改的问题
注意这里询问满足减法性质，于是可以拆成四个询问，很显然对x排序，对y维护树状数组即可
具体做法间见程序注释（如果已经懂得了分治的框架写起来是非常轻松的）
注意bzoj1176和2683空间和范围略有不同

type node=record
       op,ch,w,x,y:longint;
     end;

var c:array[0..2000010] of longint;
    a,q:array[0..210010] of node;
    ans:array[0..10010] of longint;
    ch,pre,i,n,m,x,y,x1,y1,t:longint;

function lowbit(x:longint):longint;
  begin
    exit(x and (-x));
  end;

function cmp(a,b:node):boolean;  //注意这里要三个关键字排序，x,y,修改优先，为什么要自己想想
  begin
    if a.x<b.x then exit(true)
    else if a.x=b.x then
    begin
      if a.y<b.y then exit(true)
      else if (a.y=b.y) and (a.op<b.op) then exit(true);
    end;
    exit(false);
  end;

procedure swap(var a,b:node);
  var c:node;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure sort(l,r:longint);
  var i,j:longint;
      x:node;
  begin
    i:=l;
    j:=r;
    x:=q[(l+r) shr 1];
    repeat
      while cmp(q[i],x) do inc(i);
      while cmp(x,q[j]) do dec(j);
      if not(i>j) then
      begin
        swap(q[i],q[j]);
        inc(i);
        dec(j);
      end;
    until i>j;
    if l<j then sort(l,j);
    if i<r then sort(i,r);
  end;

procedure add(x,w:longint);
  begin
    while x<=t do
    begin
      inc(c[x],w);
      x:=x+lowbit(x);
    end;
  end;

function ask(x:longint):longint;
  begin
    ask:=0;
    while x>0 do
    begin
      ask:=ask+c[x];
      x:=x-lowbit(x);
    end;
  end;

procedure cdq(l,r:longint);
  var m,i,l1,l2:longint;
  begin
    if l=r then exit;
    m:=(l+r) shr 1;
    for i:=l to r do  
    begin
      if (q[i].ch<=m) and (q[i].op=-2) then add(q[i].y,q[i].w);  //前半部分修改
      if (q[i].ch>m) and (q[i].op<>-2) then inc(ans[q[i].w],ask(q[i].y)*q[i].op);  //对后半部分查询影响
    end;
    for i:=l to r do  //树状数组清0
      if (q[i].ch<=m) and (q[i].op=-2) then add(q[i].y,-q[i].w);
    l1:=l; l2:=m+1;
    for i:=l to r do  //按时间划分操作序列
      if q[i].ch<=m then
      begin
        a[l1]:=q[i];
        inc(l1);
      end
      else begin
        a[l2]:=q[i];
        inc(l2);
      end;

    for i:=l to r do
      q[i]:=a[i];
    cdq(l,m);
    cdq(m+1,r);
  end;

begin
  readln(pre,t);
  while true do
  begin
    read(ch);
    if ch=3 then break;
    if ch=1 then
    begin
      inc(m);
      q[m].ch:=m;
      readln(q[m].x,q[m].y,q[m].w);
      q[m].op:=-2;
    end
    else begin
      inc(n); inc(m);
      readln(x,y,x1,y1);
      q[m].w:=n; q[m].ch:=m; q[m].x:=x1; q[m].y:=y1; q[m].op:=1;
      inc(m);
      q[m].w:=n; q[m].ch:=m; q[m].x:=x-1; q[m].y:=y1; q[m].op:=-1;
      inc(m);
      q[m].w:=n; q[m].ch:=m; q[m].x:=x1; q[m].y:=y-1; q[m].op:=-1;
      inc(m);
      q[m].w:=n; q[m].ch:=m; q[m].x:=x-1; q[m].y:=y-1; q[m].op:=1;
    end;
  end;
  sort(1,m);
  cdq(1,m);
  for i:=1 to n do
    writeln(ans[i]);
end.