bzoj3503

显然知道第一行就可以只道整个矩阵
但n<=40，搜索是不行的，我们设第一行为x1~xm
可以由轻易由第一行未知数推出第n+1行，这一步我们可以压成二进制位（因为只和奇偶有关）
显然n+1行必须是0，由此可以列方程高斯消元即可

var a,c:array[0..50,0..50] of longint;
    b:array[0..50,0..50] of int64;
    n,m,i,j:longint;

procedure swap(var a,b:longint);
  var c:longint;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure gauss;
  var i,j,k,p:longint;
  begin
    k:=1;
    for i:=1 to m do
    begin
      j:=k;
      while (j<=m) and (a[j,i]=0) do inc(j);
      if (j>m) then continue;
      if j<>k then
      begin
        for p:=i to m+1 do
         swap(a[k,p],a[j,p]);
      end;
      for j:=k+1 to m do
        if a[j,i]=1 then
        begin
          for p:=i to m+1 do
            a[j,p]:=a[j,p] xor a[k,p];
        end;
      inc(k);
    end;
    for i:=m downto 1 do
    begin
      c[1,i]:=a[i,m+1];
      if a[i,i]=0 then
      begin
        c[1,i]:=1;
        continue;
      end;
      for j:=i+1 to m do
        if a[i,j]=1 then c[1,i]:=c[1,i] xor c[1,j];
    end;
  end;

begin
  readln(n,m);
  for i:=1 to m do
    b[1,i]:=int64(1) shl int64(i-1);

  for i:=2 to n+1 do
    for j:=1 to m do
      b[i,j]:=b[i-1,j] xor b[i-1,j+1] xor b[i-1,j-1] xor b[i-2,j];

  for i:=1 to m do
    for j:=1 to m do
      if b[n+1,i] and (int64(1) shl int64(j-1))<>0 then a[i,j]:=1;

  gauss;
  for i:=2 to n do
    for j:=1 to m do
      c[i,j]:=c[i-1,j] xor c[i-1,j+1] xor c[i-1,j-1] xor c[i-2,j];

  for i:=1 to n do
  begin
    for j:=1 to m-1 do
      write(c[i,j],' ');
    writeln(c[i,m]);
  end;
end.