bzoj1822

显然是二分+最大流判定
但比较烦的是判断线段和圆及其内部是否有公共点
我的判断方法是错的，但是数据弱
目前只知道推公式分类讨论，如果有简单的方法求教

const inf=10000007;
type node=record
       flow,po,next:longint;
     end;
     point=record
       x,y:longint;
     end;

var e:array[0..80010] of node;
    a,b,c:array[0..205] of point;
    can:array[0..200,0..200] of boolean;
    g,cur,v,w,pre,p,numh,h:array[0..505] of longint;
    q,l,r,t,ans,mid,i,j,n,m,k,len:longint;
    ff,ch:boolean;

function dis(a,b:point):double;
  begin
    exit(sqrt(sqr(a.x-b.x)+sqr(a.y-b.y)));
  end;

function cross(a,b,c:point):double;
  begin
    cross:=abs((a.x-b.x)*(a.y-c.y)-(a.x-c.x)*(a.y-b.y));
    cross:=cross/dis(a,b);
  end;

procedure add(x,y,f:longint);
  begin
    inc(len);
    e[len].po:=y;
    e[len].flow:=f;
    e[len].next:=p[x];
    p[x]:=len;
  end;

function sap:longint;
  var u,i,j,tmp,q:longint;
  begin
    fillchar(h,sizeof(h),0);
    fillchar(numh,sizeof(numh),0);
    for i:=0 to t do
      cur[i]:=p[i];
    u:=0;
    sap:=0;
    numh[0]:=t+1;
    while h[0]<t+1 do
    begin
      i:=cur[u];
      while i<>-1 do
      begin
        j:=e[i].po;
        if (e[i].flow>0) and (h[u]=h[j]+1) then
        begin
          pre[j]:=u;
          cur[u]:=i;
          u:=j;
          if u=t then
          begin
            inc(sap);
            if sap=m then exit;
            while u<>0 do
            begin
              u:=pre[u];
              j:=cur[u];
              dec(e[j].flow);
              inc(e[j xor 1].flow);
            end;
          end;
          break;
        end;
        i:=e[i].next;
      end;
      if i=-1 then
      begin
        dec(numh[h[u]]);
        if numh[h[u]]=0 then exit;
        tmp:=t;
        q:=-1;
        i:=p[u];
        while i<>-1 do
        begin
          j:=e[i].po;
          if e[i].flow>0 then
            if h[j]<tmp then
            begin
              q:=i;
              tmp:=h[j];
            end;
          i:=e[i].next;
        end;
        h[u]:=tmp+1;
        inc(numh[h[u]]);
        cur[u]:=q;
        if u<>0 then u:=pre[u];
      end;
    end;
  end;

function check(s:longint):boolean;
  var q,i,j:longint;
  begin
    fillchar(p,sizeof(p),255);
    len:=-1;
    q:=0;
    for i:=1 to n do
    begin
      add(0,i,s div w[i]+1);
      add(i,0,0);
      if s div w[i]*w[i]>q then q:=s div w[i]*w[i];
    end;
    for i:=1 to m do
    begin
      add(i+n,t,1);
      add(t,i+n,0);
      for j:=1 to n do
        if can[i,j] then
        begin
          add(j,i+n,1);
          add(i+n,j,0);
        end;
    end;
    if sap=m then
    begin
      ans:=q;
      exit(true);
    end
    else exit(false);
  end;

begin
  readln(n,m,k);
  for i:=1 to n do
  begin
    readln(a[i].x,a[i].y,v[i],w[i]);
    if w[i]>r then r:=w[i];
  end;
  for i:=1 to m do
    readln(b[i].x,b[i].y);
  for i:=1 to k do
    readln(c[i].x,c[i].y,g[i]);
  for i:=1 to m do
  begin
    ch:=false;
    for j:=1 to n do
      if dis(b[i],a[j])<=v[j] then
      begin
        ff:=true;
        for q:=1 to k do
          if cross(b[i],a[j],c[q])<g[q] then
          begin
            ff:=false;
            break;
          end;
        if ff then
        begin
          can[i,j]:=true;
          ch:=true;
        end;
      end;

    if not ch then
    begin
      writeln(-1);
      halt;
    end;
  end;
  t:=n+m+1;
  l:=0;
  r:=r*m;
  while l<=r do
  begin
    mid:=(l+r) shr 1;
    if check(mid) then r:=ans-1 else l:=mid+1;
  end;
  writeln(ans);
end.