bzoj1030

自动机之后按照自动机上的状态转移做dp就可以了
不用矩乘还是很良心

const mo=10007;
var q,f:array[0..10010] of longint;
    trie:array[0..10010,'A'..'Z'] of longint;
    can:array[0..10010] of boolean;
    dp:array[0..105,0..10010] of longint;
    l,k,s0,ss,i,n,m,j,t:longint;
    s:string;
    c:char;

procedure bfs;
  var x,y,i,h,r:longint;
      c:char;
  begin
    h:=1;
    r:=0;
    for c:='A' to 'Z' do
      if trie[0,c]>0 then
      begin
        inc(r);
        q[r]:=trie[0,c];
      end;
    while h<=r do
    begin
      x:=q[h];
      for c:='A' to 'Z' do
        if trie[x,c]>0 then
        begin
          y:=trie[x,c];
          i:=f[x];
          while (i>0) and (trie[i,c]=0) do i:=f[i];
          if can[trie[i,c]] then can[y]:=true;  //这是一个易错点，考虑下shen和he这两个单词
          f[y]:=trie[i,c];
          inc(r);
          q[r]:=y;
        end;
      inc(h);
    end;
  end;

begin
  readln(n,m);
  f[0]:=-1;
  for i:=1 to n do
  begin
    readln(s);
    j:=0;
    l:=length(s);
    for k:=1 to l do
    begin
      if trie[j,s[k]]=0 then
      begin
        inc(t);
        trie[j,s[k]]:=t;
      end;
      j:=trie[j,s[k]];
    end;
    can[j]:=true;
  end;
  bfs;
  s0:=1;
  for i:=1 to m do
    s0:=s0*26 mod mo;
  dp[0,0]:=1;
  for i:=1 to m do
    for j:=0 to t do
    begin
      if can[j] then continue;
      for c:='A' to 'Z' do
      begin
        k:=j;
        while (k<>-1) do
        begin
          if trie[k,c]>0 then
          begin
            dp[i,trie[k,c]]:=(dp[i,trie[k,c]]+dp[i-1,j]) mod mo;
            break;
          end;
          k:=f[k];
        end;
        if k=-1 then
          dp[i,0]:=(dp[i,0]+dp[i-1,j]) mod mo;
      end;
    end;

  ss:=0;
  for i:=0 to t do
    if not can[i] then ss:=(ss+dp[m,i]) mod mo;
  writeln((s0+mo-ss) mod mo);
end.