bzoj2333

好题，先离线把连通块变成连续的区间
每次连通块合并就相当于两个区间合并
这样就轻易的用线段树解决了

type node=record
       wh:string[2];
       x,y:longint;
     end;

var lazy,tree:array[0..300010*4] of longint;
    q:array[0..300010] of node;
    a,b,c,last,next,fa:array[0..300010] of longint;
    i,n,m,x,y,t:longint;
    ch:char;

procedure swap(var a,b:longint);
  var c:longint;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

function max(a,b:longint):longint;
  begin
    if a>b then exit(a) else exit(b);
  end;

function getf(x:longint):longint;
  begin
    if fa[x]<>x then fa[x]:=getf(fa[x]);
    exit(fa[x]);
  end;

procedure push(i:longint);
  begin
    inc(lazy[i*2],lazy[i]);
    inc(tree[i*2],lazy[i]);
    inc(lazy[i*2+1],lazy[i]);
    inc(tree[i*2+1],lazy[i]);
    lazy[i]:=0;
  end;

function ask(i,l,r,x,y:longint):longint;
  var m,s:longint;
  begin
    if (x<=l) and (y>=r) then exit(tree[i])
    else begin
      if lazy[i]<>0 then push(i);
      m:=(l+r) shr 1;
      s:=-2147483647;
      if x<=m then s:=ask(i*2,l,m,x,y);
      if y>m then s:=max(s,ask(i*2+1,m+1,r,x,y));
      exit(s);
    end;
  end;

procedure add(i,l,r,x,y,z:longint);
  var m:longint;
  begin
    if (x<=l) and (y>=r) then
    begin
      inc(tree[i],z);
      inc(lazy[i],z);
    end
    else begin
      if lazy[i]<>0 then push(i);
      m:=(l+r) shr 1;
      if x<=m then add(i*2,l,m,x,y,z);
      if y>m then add(i*2+1,m+1,r,x,y,z);
      tree[i]:=max(tree[i*2],tree[i*2+1]);
    end;
  end;

procedure build(i,l,r:longint);
  var m:longint;
  begin
    if l=r then tree[i]:=a[c[l]]
    else begin
      m:=(l+r) shr 1;
      build(i*2,l,m);
      build(i*2+1,m+1,r);
      tree[i]:=max(tree[i*2],tree[i*2+1]);
    end;
  end;

begin
  readln(n);
  for i:=1 to n do
  begin
    read(a[i]);
    fa[i]:=i;
    last[i]:=i;
  end;
  readln(m);
  for i:=1 to m do
  begin
    read(ch);
    q[i].wh:=ch;
    read(ch);
    q[i].wh:=q[i].wh+ch;
    if q[i].wh='U ' then
    begin
      readln(q[i].x,q[i].y);
      x:=getf(q[i].x);
      y:=getf(q[i].y);
      if x=y then continue;
      fa[y]:=x;
      next[last[x]]:=y;
      last[x]:=last[y];
    end
    else if (q[i].wh='A1') or (q[i].wh='A2') then
      readln(q[i].x,q[i].y)
    else if (q[i].wh='F3') then readln
    else readln(q[i].x);
  end;

  for i:=1 to n do
    if fa[i]=i then
    begin
      x:=i;
      while x<>0 do
      begin
        inc(t);
        b[x]:=t;
        c[t]:=x;
        x:=next[x];
      end;
    end;

  build(1,1,n);
  for i:=1 to n do
  begin
    fa[i]:=i;
    last[i]:=i;
  end;

  for i:=1 to m do
    if q[i].wh='U ' then
    begin
      x:=getf(q[i].x);
      y:=getf(q[i].y);
      if x=y then continue;
      fa[y]:=x;
      last[x]:=last[y];
    end
    else if q[i].wh='A1' then
      add(1,1,n,b[q[i].x],b[q[i].x],q[i].y)
    else if q[i].wh='A2' then
    begin
      x:=getf(q[i].x);
      y:=last[x];
      add(1,1,n,b[x],b[y],q[i].y);
    end
    else if q[i].wh='A3' then
    begin
      inc(tree[1],q[i].x);
      inc(lazy[1],q[i].x);
    end
    else if q[i].wh='F1' then
      writeln(ask(1,1,n,b[q[i].x],b[q[i].x]))
    else if q[i].wh='F2' then
    begin
      x:=getf(q[i].x);
      y:=last[x];
      writeln(ask(1,1,n,b[x],b[y]));
    end
    else writeln(tree[1]);
end.