bzoj1415

比较简单的数学期望，先预处理出当聪聪在i，可可在j时聪聪往哪个点走
然后做dp即可，我用了记忆化搜索实现

type node=record
       po,next:longint;
     end;

var d,pos:array[0..1010,0..1010] of longint;
    f:array[0..1010,0..1010] of double;
    v:array[0..1010] of boolean;
    e:array[0..2010] of node;
    c,p,q:array[0..2010] of longint;
    len,s,t,i,j,n,m,x,y:longint;

procedure add(x,y:longint);
  begin
    inc(len);
    e[len].po:=y;
    e[len].next:=p[x];
    p[x]:=len;
  end;

procedure bfs(s:longint);
  var f,r,i,x,y:longint;
  begin
    d[s,s]:=0;
    fillchar(v,sizeof(v),false);
    v[s]:=true;
    f:=1;
    r:=0;
    i:=p[s];
    while i<>0 do
    begin
      y:=e[i].po;
      v[y]:=true;
      inc(r);
      q[r]:=y;
      d[s,y]:=1;
      pos[s,y]:=y;
      i:=e[i].next;
    end;
    while f<=r do
    begin
      x:=q[f];
      i:=p[x];
      while i<>0 do
      begin
        y:=e[i].po;
        if not v[y] then
        begin
          d[s,y]:=d[s,x]+1;
          pos[s,y]:=pos[s,x];
          v[y]:=true;
          inc(r);
          q[r]:=y;
        end
        else if (d[s,y]=d[s,x]+1) and (pos[s,x]<pos[s,y]) then
          pos[s,y]:=pos[s,x];

        i:=e[i].next;
      end;
      inc(f);
    end;
  end;

function dfs(x,y:longint):double;
  var i,w:longint;
  begin
    if x=y then exit(0);
    if (pos[x,y]=y) or (pos[pos[x,y],y]=y) then exit(1);
    if f[x,y]<>-1 then exit(f[x,y]);
    i:=p[y];
    f[x,y]:=dfs(pos[pos[x,y],y],y);
    while i<>0 do
    begin
      w:=e[i].po;
      f[x,y]:=f[x,y]+dfs(pos[pos[x,y],y],w);
      i:=e[i].next;
    end;
    f[x,y]:=f[x,y]/(c[y]+1)+1;
    exit(f[x,y]);
  end;

begin
  readln(n,m);
  readln(s,t);
  for i:=1 to m do
  begin
    readln(x,y);
    add(x,y);
    add(y,x);
    inc(c[x]);
    inc(c[y]);
  end;
  for i:=1 to n do
  begin
    for j:=1 to n do
      f[i,j]:=-1;
    pos[i,i]:=i;
    f[i,i]:=0;
    bfs(i);
  end;
  writeln(dfs(s,t):0:3);
end.