bzoj1912

由于k只有2，所以我们分类讨论
显然当k=1时，我们只要连一条最长的路径即可就是树的直径L
少走了L-1条边
如果k=2时，我们再次连边成环后
如果成环路径与上一次的最长路径没有相同的边，那少走的边数是路径长l-1
如果有相同的边，那么相同的边一共还是会走两次，少走的边数是l-1-2*same
因此我们只要把第一次找的的最长路径上的边标记为-1，再做一次树形dp即可

type node=record
       po,len,next:longint;
     end;

var w:array[0..200010] of node;
    f,p1,p2,p:array[0..100010] of longint;
    v:array[0..100010] of boolean;
    i,ans,loc,maxx,t,n,k,x,y:longint;

function max(a,b:longint):longint;
  begin
    if a>b then exit(a) else exit(b);
  end;

procedure add(x,y:longint);
  begin
    inc(t);
    w[t].po:=y;
    w[t].len:=1;
    w[t].next:=p[x];
    p[x]:=t;
  end;

procedure dfs(x:longint);
  var i,y,s1,s2:longint;
  begin
    i:=p[x];
    v[x]:=true;
    s1:=0;
    s2:=0;
    while i<>-1 do
    begin
      y:=w[i].po;
      if not v[y] then
      begin
        dfs(y);
        if f[y]+w[i].len>s1 then
        begin
          s2:=s1;
          p2[x]:=p1[x];
          s1:=f[y]+w[i].len;
          p1[x]:=i;
        end
        else if (s2<f[y]+w[i].len) then
        begin
          s2:=f[y]+w[i].len;
          p2[x]:=i;
        end;
      end;
      i:=w[i].next;
    end;
 //   writeln(x,' ',s1,' ',s2);
    f[x]:=s1;
    if maxx<s1+s2 then
    begin
      maxx:=s1+s2;
      loc:=x;
    end;
  end;

begin
  t:=-1;
  fillchar(p,sizeof(p),255);
  fillchar(p1,sizeof(p1),255);
  fillchar(p2,sizeof(p2),255);
  readln(n,k);
  for i:=1 to n-1 do
  begin
    readln(x,y);
    add(x,y);
    add(y,x);
  end;
  dfs(1);
  ans:=2*(n-1)-maxx+1;
  if k=2 then
  begin
    maxx:=0;
    w[p1[loc]].len:=-1;
    w[p2[loc]].len:=-1;
    x:=w[p1[loc]].po;
    while p1[x]<>-1 do
    begin
      w[p1[x]].len:=-1;
      x:=w[p1[x]].po;
    end;
    x:=w[p2[loc]].po;
    while p1[x]<>-1 do
    begin
      w[p1[x]].len:=-1;
      x:=w[p1[x]].po;
    end;
    fillchar(v,sizeof(v),false);
    fillchar(f,sizeof(f),0);
    dfs(1);
    ans:=ans-maxx+1;
  end;
  writeln(ans);
end.