bzoj1297

首先学习是学习矩阵乘法在邻接矩阵的应用
ab两点经过k条边的路径数就等于图的邻接矩阵G的k次幂之后G[a,b]的值
但这道题问的是经过长度为k的路径数
考虑到每条边的长度最长只有9，所以我们把一个点拆成9个点，
i1~i9 顺次相连长度为1，i9为出点
对于长度为k的边eij，连边i9-->j(10-k) 长度为1
这样图中的每条边的长度都变成了1，就相当于求k条边的路径数了

const mo=2009;
var ans,a,b,c:array[0..92,0..92] of longint;
    d:array[0..30] of longint;
    i,j,k,x,n,m:longint;
    ch:char;

procedure mul;
  var i,j,k:longint;
  begin
    for i:=1 to n do
      for j:=1 to n do
      begin
        ans[i,j]:=0;
        for k:=1 to n do
          ans[i,j]:=(ans[i,j]+a[i,k]*b[k,j] mod mo) mod mo;
      end;
   end;

procedure quick(x:longint);
  var i,j,p,q:longint;
  begin
    j:=0;
    while x<>0 do
    begin
      inc(j);
      d[j]:=x mod 2;
      x:=x shr 1;
    end;
    fillchar(ans,sizeof(ans),0);
    for i:=1 to n do
      ans[i,i]:=1;
    for i:=j downto 1 do
    begin
      a:=ans;
      b:=ans;
      mul;
      if d[i]=1 then
      begin
        a:=ans;
        b:=c;
        mul;
      end;
    end;
  end;

begin
  readln(n,m);
  for i:=1 to n do
  begin
    for j:=1 to n do
    begin
      read(ch);
      x:=ord(ch)-48;
      if x<>0 then
      begin
        c[i*9,j*9-x+1]:=1;
        for k:=j*9-x+1 to j*9-1 do
          c[k,k+1]:=1;
      end;
    end;
    readln;
  end;
  n:=n*9;
  quick(m);
  writeln(ans[9,n]);
end.