bzoj3295

没什么好说的，树套树应该随便搞
我在128MB空间下大胆的写了主席树
当然要把原树和修改树分开来建
没有然后了

type node=record
       l,r,s:longint;
     end;

var tree:array[0..10000010] of node;
    c:array[0..100010] of int64;
    h,ph,a,b,d1,d2:array[0..100010] of longint;
    dd1,dd2:array[0..100,0..100] of longint;
    d,t1,t2,i,x,y,n,m,t:longint;
    ans:int64;

function lowbit(x:longint):longint;
  begin
    exit(x and (-x));
  end;

procedure add(x:longint);
  begin
    while x<=n do
    begin
      c[x]:=c[x]+1;
      x:=x+lowbit(x);
    end;
  end;

function get(x:longint):int64;
  begin
    get:=0;
    while x>0 do
    begin
      get:=get+c[x];
      x:=x-lowbit(x);
    end;
  end;

procedure update(i:longint);
  begin
    tree[i].s:=tree[tree[i].l].s+tree[tree[i].r].s;
  end;

function build(l,r:longint):longint;
  var m,q:longint;
  begin
    inc(t);
    if l=r then
      exit(t)
    else begin
      m:=(l+r) shr 1;
      q:=t;
      tree[q].l:=build(l,m);
      tree[q].r:=build(m+1,r);
      exit(q);
    end;
  end;

function insert(l,r,last,x,y:longint):longint;
  var m,q:longint;
  begin
    inc(t);
    if l=r then
    begin
      tree[t].s:=tree[last].s+y;
      exit(t);
    end
    else begin
      m:=(l+r) shr 1;
      q:=t;
      if x<=m then
      begin
        tree[q].r:=tree[last].r;
        last:=tree[last].l;
        tree[q].l:=insert(l,m,last,x,y);
      end
      else begin
        tree[q].l:=tree[last].l;
        last:=tree[last].r;
        tree[q].r:=insert(m+1,r,last,x,y);
      end;
      update(q);
      exit(q);
    end;
  end;

function getans(l,r,x,y:longint):longint;
  var m,s,i:longint;
  begin
    if (x<=l) and (y>=r) then
    begin
      s:=0;
      for i:=1 to t2 do
        s:=s+tree[d2[i]].s;
      for i:=1 to t1 do
        s:=s-tree[d1[i]].s;
      exit(s);
    end
    else begin
      m:=(l+r) shr 1;
      s:=0;
      if (x<=m) then
      begin
        inc(d);
        for i:=1 to t1 do
        begin
          dd1[d,i]:=d1[i];
          d1[i]:=tree[d1[i]].l;
        end;
        for i:=1 to t2 do
        begin
          dd2[d,i]:=d2[i];
          d2[i]:=tree[d2[i]].l;
        end;
        s:=s+getans(l,m,x,y);
        for i:=1 to t1 do
          d1[i]:=dd1[d,i];
        for i:=1 to t2 do
          d2[i]:=dd2[d,i];
        dec(d);
      end;
      if y>m then
      begin
        for i:=1 to t1 do
          d1[i]:=tree[d1[i]].r;
        for i:=1 to t2 do
          d2[i]:=tree[d2[i]].r;
        s:=s+getans(m+1,r,x,y);
      end;
      exit(s);
    end;
  end;

function ask(l,r,x,y:longint):longint;
  var i:longint;
  begin
    if r=0 then exit(0);
    if l=n+1 then exit(0);
    if x=n+1 then exit(0);
    if y=0 then exit(0);
    dec(l);
    t1:=1;
    t2:=1;
    d1[1]:=ph[l];
    d2[1]:=ph[r];
    i:=l;
    while i>0 do
    begin
      if h[i]<>0 then
      begin
        inc(t1);
        d1[t1]:=h[i];
      end;
      i:=i-lowbit(i);
    end;
    i:=r;
    while i>0 do
    begin
      if h[i]<>0 then
      begin
        inc(t2);
        d2[t2]:=h[i];
      end;
      i:=i-lowbit(i);
    end;
    d:=0;
    exit(getans(1,n,x,y));
  end;

procedure del(x,y:longint);
  begin
    while x<=n do
    begin
      h[x]:=insert(1,n,h[x],y,-1);
      x:=x+lowbit(x);
    end;
  end;

begin
  readln(n,m);
  for i:=1 to n do
  begin
    readln(a[i]);
    b[a[i]]:=i;
  end;
  for i:=n downto 1 do
  begin
    ans:=ans+get(a[i]-1);
    add(a[i]);
  end;
  h[0]:=build(1,n);
  ph[0]:=h[0];
  for i:=1 to n do
    ph[i]:=insert(1,n,ph[i-1],a[i],1);
  for i:=1 to m do
  begin
    readln(x);
    y:=b[x];
    writeln(ans);
    ans:=ans-ask(1,y-1,x+1,n)-ask(y+1,n,1,x-1);
    del(y,x);
  end;
end.