bzoj3224

平衡树模板在此！
写了treap（话说好久没写splay了）
注意对相同元素的处理

UPD：其实这里处理的不好，每个点可以代表一个元素值，然后记录出现次数即可，不用新添一个点

const rd=200007;
var fa,key,a,count:array[0..200010] of longint;
    son:array[0..200010,1..2] of longint;
    t,root,ch,x,i,n:longint;

procedure clear(x:longint);
  begin
    son[x,1]:=0;
    son[x,2]:=0;
    fa[x]:=0;
    count[x]:=1;
    fa[0]:=-1;
    count[0]:=0;
  end;

procedure update(x:longint);
  begin
    count[x]:=count[son[x,1]]+count[son[x,2]]+1;
  end;

procedure rotate(x,w:longint);
  var y:longint;
  begin
    y:=fa[x];
    if fa[y]<>0 then
    begin
      if son[fa[y],1]=y then son[fa[y],1]:=x
      else son[fa[y],2]:=x;
    end
    else root:=x;
    fa[x]:=fa[y];
    son[y,3-w]:=son[x,w];
    fa[son[x,w]]:=y;
    son[x,w]:=y;
    fa[y]:=x;
    update(y);
    update(x);
  end;

procedure up(i:longint);
  var j:longint;
  begin
    j:=fa[i];
    while (j<>0) and (key[j]>key[i]) do
    begin
      if son[j,1]=i then rotate(i,2)
      else rotate(i,1);
      j:=fa[i];
    end;
  end;

procedure sift(i:longint);
  var j1,j2:longint;
  begin
    repeat
      j1:=son[i,1];
      j2:=son[i,2];
      if (j1=0) and (j2=0) then break;
      if (j1=0) then
        rotate(j2,1)
      else if j2=0 then
        rotate(j1,2)
      else begin
        if (key[j1]>key[j2]) then
          rotate(j2,1)
        else rotate(j1,2);
      end;
    until false;
  end;

function find(x:longint):longint;
  var p:longint;
  begin
    p:=root;
    while true do
    begin
      if a[p]=x then exit(p);
      if a[p]>x then p:=son[p,1]
      else p:=son[p,2];
    end;
  end;

procedure insert(x:longint);
  var p:longint;
  begin
    inc(t);
    key[t]:=trunc(random*rd)+1;
    a[t]:=x;
    clear(t);
    if root=0 then root:=t
    else begin
      p:=root;
      repeat
        inc(count[p]);
        if a[p]>x then
        begin
          if son[p,1]=0 then break;
          p:=son[p,1];
        end
        else begin
          if son[p,2]=0 then break;
          p:=son[p,2];
        end;
      until false;
      fa[t]:=p;
      if a[p]>x then son[p,1]:=t else son[p,2]:=t;
      up(t);
    end;
  end;

procedure delete(x:longint);
  var i,p:longint;
  begin
    i:=find(x);
    sift(i);
    if fa[i]=0 then root:=0;
    p:=fa[i];
    while p<>0 do
    begin
      dec(count[p]);
      p:=fa[p];
    end;
    if son[fa[i],1]=i then son[fa[i],1]:=0
    else son[fa[i],2]:=0;
    clear(i);
  end;

function kth(x:longint):longint;
  var p:longint;
  begin
    p:=root;
    while true do
    begin
      if count[son[p,1]]+1=x then exit(a[p]);
      if count[son[p,1]]+1>x then p:=son[p,1]
      else begin
        x:=x-count[son[p,1]]-1;
        p:=son[p,2];
      end;
    end;
  end;

function rank(x:longint):longint;
  var p:longint;
  begin
    p:=root;
    rank:=1;
    while p<>0 do
    begin
      if a[p]>=x then p:=son[p,1]  //注意这里的等号，因为是要找最小的排名
      else begin
        rank:=rank+count[son[p,1]]+1;
        p:=son[p,2];
      end;
    end;
  end;

function pre(p,x:longint):longint;
  begin
    if p=0 then exit(-1);
    if a[p]>=x then exit(pre(son[p,1],x))
    else begin
      pre:=pre(son[p,2],x);
      if pre=-1 then pre:=a[p];
    end;
  end;

function succ(p,x:longint):longint;
  begin
    if p=0 then exit(-1);
    if a[p]<=x then exit(succ(son[p,2],x))
    else begin
      succ:=succ(son[p,1],x);
      if succ=-1 then succ:=a[p];
    end;
  end;

begin
  randomize;
  readln(n);
  for i:=1 to n do
  begin
    readln(ch,x);
    if ch=1 then
      insert(x)
    else if ch=2 then
      delete(x)
    else if ch=3 then
      writeln(rank(x))
    else if ch=4 then
      writeln(kth(x))
    else if ch=5 then
      writeln(pre(root,x))
    else writeln(succ(root,x));
  end;
end.