bzoj3124

很好的一道treedp，当然也挺烦的
首先不难想到先求出一个直径，然后穷举每条边，看他删除之后直径大小是否会变，变了的话就是必须经过的边
下面我们就要想怎么优化，本人语言表达略差，还是配合程序说吧。

type node=record
       point,next:longint;
       cost:int64;
     end;

var f:array[0..200010] of int64;
    pr,fr:array[0..200010,0..2] of longint;
    g,h:array[0..200010,0..2] of int64;
    p:array[0..200010] of longint;
    edge:array[0..400010] of node;
    v:array[0..200010] of boolean;
    i,n,len,ans,x,y,z:longint;

procedure add(x,y,z:longint);
  begin
    inc(len);
    edge[len].point:=y;
    edge[len].cost:=z;
    edge[len].next:=p[x];
    p[x]:=len;
  end;

function max(a,b:int64):int64;
  begin
    if a>b then exit(a) else exit(b);
  end;

procedure dp(x:longint);
  var i,y:longint;
  begin
    i:=p[x];
    v[x]:=true;
    while i<>-1 do
    begin
      y:=edge[i].point;
      if not v[y] then
      begin
        dp(y);
        f[x]:=max(f[x],f[y]);  //f[]表示以x为根的子树中最长的路径长
        if g[y,0]+edge[i].cost>g[x,0] then  //维护以x为根走到底最长的3条路径（显然不能有两条路径经过同一个孩子）
//这里要维护3条，因为要考虑删边的时候碰巧干掉了其中一条，如果单纯求树的直径的时候只要维护最长和次长即可）
        begin
          g[x,2]:=g[x,1];
          fr[x,2]:=fr[x,1];
          g[x,1]:=g[x,0];
          fr[x,1]:=fr[x,0];
          g[x,0]:=g[y,0]+edge[i].cost;
          fr[x,0]:=y;  //从哪转移来的
        end
        else if (g[y,0]+edge[i].cost>g[x,1]) then
        begin
          g[x,2]:=g[x,1];
          fr[x,2]:=fr[x,1];
          g[x,1]:=g[y,0]+edge[i].cost;
          fr[x,1]:=y;
        end
        else if (g[y,0]+edge[i].cost>g[x,2]) then
        begin
          g[x,2]:=g[y,0]+edge[i].cost;
          fr[x,2]:=y;
        end;
        if f[y]>h[x,0] then  //h维护的是以x为根的子树中最长的2条路径（不经过根）
        begin
          h[x,1]:=h[x,0];
          pr[x,1]:=pr[x,0];
          h[x,0]:=f[y];
          pr[x,0]:=y;  //从哪转移来的
        end
        else if f[y]>h[x,1] then
        begin
          h[x,1]:=f[y];
          pr[x,1]:=y;
        end;
      end;
      i:=edge[i].next;
    end;
    f[x]:=max(f[x],g[x,1]+g[x,0]);
  end;

procedure dfs(x:longint;l,d:int64); //l表示以x为终点且不是起点x的后辈的最长路径，d表示之前搜索到的不经过x的最长路径
  var i,y:longint;
      l1,l2,l3:int64;
  begin
    i:=p[x];
    v[x]:=true;
    while i<>-1 do
    begin
      y:=edge[i].point;
      if not v[y] then   //大批的分类讨论
      begin
        l1:=f[y];
        if y=pr[x,0] then l2:=h[x,1]
        else l2:=h[x,0];
        l2:=max(l2,d);

        if y=fr[x,0] then l2:=max(l2,g[x,1]+g[x,2])
        else if y=fr[x,1] then l2:=max(l2,g[x,0]+g[x,2])
        else l2:=max(l2,g[x,0]+g[x,1]);

        if y=fr[x,0] then l3:=g[x,1]
        else l3:=g[x,0];
        l2:=max(l2,l+l3);
        if max(l1,l2)<f[1] then inc(ans);
        dfs(y,max(l3,l)+edge[i].cost,l2);
      end;
      i:=edge[i].next;
    end;
  end;

begin
  readln(n);
  fillchar(p,sizeof(p),255);
  for i:=1 to n-1 do
  begin
    readln(x,y,z);
    add(x,y,z);
    add(y,x,z);
  end;
  dp(1);
  writeln(f[1]);
  fillchar(v,sizeof(v),false);
  ans:=0;
  dfs(1,0,0);
  writeln(ans);
end.