bzoj1016

这道题主要利用了最小生成树的两个性质

1. 最小生成树每种边权的数目固定不变

2. 最小生成树每种边权带来的连通状况一定唯一

由于每种边权的只有不到10种，所以直接穷举然后乘法原理即可

const mo=31011;
type node=record
       x,y,w:longint;
     end;

var a:array[0..10010] of node;
    fa,rank,v:array[0..10010] of longint;
    sum,ans,k1,k2,s,i,j,n,m,p,k:longint;

function getf(x:longint):longint;
  begin
    if fa[x]<>x then fa[x]:=getf(fa[x]);
    exit(fa[x]);
  end;


procedure swap(var a,b:node);
  var c:node;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure sort(l,r:longint);
  var i,j,x,y:longint;
  begin
    i:=l;
    j:=r;
    x:=a[(l+r) shr 1].w;
    repeat
      while a[i].w<x do inc(i);
      while x<a[j].w do dec(j);
      if not(i>j) then
      begin
        swap(a[i],a[j]);
        inc(i);
        j:=j-1;
      end;
    until i>j;
    if l<j then sort(l,j);
    if i<r then sort(i,r);
  end;

function calc(x:longint):longint;
  begin
    calc:=0;
    while x>0 do
    begin
      calc:=calc+x mod 2;
      x:=x shr 1;
    end;
  end;

function check(p,cur:longint):longint;
  var i,res,tot:longint;
  begin
    for i:=1 to n do
      fa[i]:=i;
    tot:=0;
    res:=0;
    for i:=p to j-1 do
    begin
      if cur and 1=1 then
      begin
        k1:=getf(a[i].x);
        k2:=getf(a[i].y);
        if k1<>k2 then
        begin
          fa[k1]:=k2;
          inc(tot);
          res:=res+a[i].w;
        end;
      end;
      cur:=cur shr 1;
    end;
    for i:=1 to m do
    begin
      if a[i].w=a[j-1].w then continue;
      k1:=getf(a[i].x);
      k2:=getf(a[i].y);
      if k1<>k2 then
      begin
        fa[k1]:=k2;
        inc(tot);
        res:=res+a[i].w;
      end;
    end;
    if (res=sum) and (tot=n-1) then exit(1) else exit(0);
  end;

begin
  readln(n,m);
  for i:=1 to m do
    readln(a[i].x,a[i].y,a[i].w);
  sort(1,m);
  for i:=1 to n do
    fa[i]:=i;
  rank[1]:=1;
  p:=1;
  for i:=2 to m do
  begin
    if a[i].w<>a[i-1].w then inc(p);
    rank[i]:=p;
  end;
  i:=0;
  j:=0;
  while i<n-1 do
  begin
    inc(j);
    k1:=getf(a[j].x);
    k2:=getf(a[j].y);
    if k1<>k2 then
    begin
      fa[k1]:=k2;
      inc(i);
      inc(v[rank[j]]);
      sum:=sum+a[j].w;
    end;
  end;
  if i<n-1 then
  begin
    writeln(0);
    halt;
  end;
  ans:=1;
  i:=1;
  while i<=m do
  begin
    j:=i+1;
    while a[i].w=a[j].w do inc(j);
    if v[rank[i]]>0 then
    begin
      s:=0;
      for k:=0 to 1 shl (j-i)-1 do
        if calc(k)=v[rank[i]] then s:=s+check(i,k);
      ans:=ans*s mod mo;
    end;
    i:=j;
  end;
  writeln(ans);
end.