bzoj2242

1. 快速幂

2. 扩展欧几里得

3. baby-step-giant-step

可以自行baidu

程序附部分注释

const key=1000007;
type link=^node;
     node=record
       re,wh:longint;
       next:link;
     end;

var hash:array[0..key] of link;
    a:array[0..100] of longint;
    j,g,ans,w,i,n,ch,t,p,z,y:longint;
    x,step,k,now:int64;

function quick(y,z,p:longint):int64;
  var t,i:longint;
  begin
    quick:=1;
    t:=0;
    while z<>0 do
    begin
      inc(t);
      a[t]:=z mod 2;
      z:=z div 2;
    end;
    for i:=t downto 1 do
    begin
      quick:=sqr(quick) mod p;
      if a[i]=1 then quick:=quick*y mod p;
    end;
  end;

function gcd(a,b:longint):longint;
  begin
    if b=0 then exit(a)
    else exit(gcd(b,a mod b));
  end;

procedure exgcd(a,b:longint;var x,y:int64);  //扩展欧几里得
  var xx,yy:int64;
  begin
    if b=0 then
    begin
      x:=1;
      y:=0;
    end
    else begin
      exgcd(b,a mod b,x,y);
      xx:=x;
      yy:=y;
      x:=yy;
      y:=xx-(a div b)*yy;
    end;
  end;

procedure add(x,i:longint);
  var p:link;
  begin
    w:=x mod key;
    p:=hash[w];
    while p<>nil do
    begin
      if p^.re=x then break;
      p:=p^.next;
    end;
    if p=nil then
    begin
      new(p);
      p^.re:=x;
      p^.wh:=i;
      p^.next:=hash[w];
      hash[w]:=p;
    end;
  end;

function find(x:longint):longint;
  var p:link;
  begin
    find:=-1;
    w:=x mod key;
    p:=hash[w];
    while p<>nil do
    begin
      if p^.re=x then exit(p^.wh);
      p:=p^.next;
    end;
  end;

begin
  readln(n,ch);
  for i:=1 to n do
  begin
    readln(y,z,p);
    if ch=1 then
      writeln(quick(y,z,p))  //快速幂不多说
    else if ch=2 then
    begin
      g:=gcd(y,p);
      if z mod g<>0 then   //先判断线性模方程是否有解
      begin
        writeln('Orz, I cannot find x!');
        continue;
      end;
      y:=y div g;
      p:=p div g;
      z:=z div g;
      exgcd(y,p,x,k);  //转化为二元一次不定方程
      x:=((x*z mod p)+p) mod p;  //注意是最小非负数
      writeln(x);
    end
    else begin
      z:=z mod p;
      t:=trunc(sqrt(p))+1;  当t选址为根号p时时间复杂度最优
      for j:=0 to key do
        hash[j]:=nil;
      now:=1;
      add(1,0);
      for j:=1 to t do   //求出a^i mod p（0<=i<=t) 的值，并映射到hash上，每个模保留最小的i
      begin
        now:=now*y mod p;
        add(now,j);
      end;
      g:=gcd(now,p);
      if g<>1 then      //求出a^t关于mod p的逆元，没有逆元则无解
      begin
        writeln('Orz, I cannot find x!');
        continue;
      end
      else begin
        now:=now div g;
        w:=p div g;
      end;
      exgcd(now,w,x,k);
      x:=(x+w) mod w;
      ans:=-1;
      step:=z;
      for j:=0 to t-1 do
      begin
        k:=find(step);   //大小步寻找  对于a^it ~ a^(i+1)t-1  (0<=i<=t-1) 寻找可行解
//存在可行解即存在hash中存在模=z*x^i mod p （x表示a^t的逆元） 
        if k>-1 then
        begin
          ans:=k+j*t;
          break;
        end;
        step:=step*x mod p;
      end;
      if ans=-1 then writeln('Orz, I cannot find x!')
      else writeln(ans);
    end;
  end;
end.