bzoj1085

肯定是搜索题无疑问，

首先要求在15步以内（包括15步）到达目标状态，也就是限定了搜索的深度，于是我们用dfs更合适

但这样复杂度仍然太大，原因就是我们在搜索中做了很多很不优的尝试

考虑当前状态若与目标状态有x处不相同，我们至少要移动x-1步才能成功

如果当前移动次数+x-1>=已找到的最小移动次数（没找到就为16），那么再往下移动肯定是没有意义的

这样我们就可以构造出估价函数，大大优化时间复杂度

const dx:array[1..8] of integer=(-1,1,-1,1,-2,-2,2,2);
      dy:array[1..8] of integer=(2,2,-2,-2,-1,1,-1,1);
      en:array[1..5,1..5] of integer=((1,1,1,1,1),
                                      (0,1,1,1,1),
                                      (0,0,-1,1,1),
                                      (0,0,0,0,1),
                                      (0,0,0,0,0));
var num,a:array[0..10,0..10] of integer;
    k,min,x0,y0,x1,y1,i,j,t:longint;
    s:string;

procedure swap(var a,b:integer);
  var c:integer;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

function check:longint;
  var i,j:integer;
  begin
    check:=0;
    for i:=1 to 5 do
      for j:=1 to 5 do
        if a[i,j]<>en[i,j] then inc(check);
    exit(check-1);
  end;

procedure dfs(x,y,d:integer);
  var xx,yy,i,p:integer;
  begin
    if d>=min then exit;
    p:=check;
    if p=-1 then
    begin
      min:=d;
      exit;
    end;
    if p+d>=min then exit;
    for i:=1 to 8 do
    begin
      xx:=x+dx[i];
      yy:=y+dy[i];
      if (xx>0) and (xx<=5) and (yy>0) and (yy<=5) then
      begin
        swap(a[x,y],a[xx,yy]);
        dfs(xx,yy,d+1);
        swap(a[x,y],a[xx,yy]);
      end;
    end;
  end;

begin
  readln(t);
  while t>0 do
  begin
    min:=16;
    k:=0;
    for i:=1 to 5 do
    begin
      readln(s);
      for j:=1 to 5 do
      begin
        if s[j]='*' then
        begin
          x0:=i;
          y0:=j;
          a[i,j]:=-1;
        end
        else a[i,j]:=ord(s[j])-48;
      end;
    end;
    dfs(x0,y0,0);
    if min=16 then writeln(-1) else writeln(min);
    dec(t);
  end;
end.