bzoj2661

不难想到，先枚举建图然后跑最大费用最大流

也不难想到一种将每个数拆成两个点i1,i2，所有满足条件的数之间

把所有满足条件之间的数x,y连边x1--->y2，y1--->x2,流量为1，费用为（x+y）

相当于流量费用都变成了原来的2倍

最后再除一下即可

const inf=10000007;
type node=record
       point,flow,cost,next:longint;
     end;

var edge:array[0..200010] of node;
    v:array[0..5010] of boolean;
    q:array[0..500010] of longint;
    pre,d,cur,p:array[0..5010] of longint;
    k,ans,len,a,b,i,j,t:longint;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

procedure add(x,y,f,c:longint);
  begin
    inc(len);
    edge[len].flow:=f;
    edge[len].point:=y;
    edge[len].cost:=c;
    edge[len].next:=p[x];
    p[x]:=len;
  end;

function gcd(x,y:longint):longint;
  begin
    if y=0 then exit(x)
    else exit(gcd(y,x mod y));
  end;

function spfa:boolean;
  var i,j,x,y,f,r:longint;
  begin
    for i:=0 to t do
      d[i]:=-inf;
    fillchar(v,sizeof(v),false);
    d[0]:=0;
    f:=1;
    r:=1;
    q[0]:=0;
    while f<=r do
    begin
      x:=q[f];
      v[x]:=false;
      i:=p[x];
      while i<>-1 do
      begin
        y:=edge[i].point;
        if edge[i].flow>0 then
          if d[y]<d[x]+edge[i].cost then
          begin
            d[y]:=d[x]+edge[i].cost;
            pre[y]:=x;
            cur[y]:=i;
            if not v[y] then
            begin
              v[y]:=true;
              inc(r);
              q[r]:=y;
            end;
          end;
        i:=edge[i].next;
      end;
      inc(f);
    end;
    if d[t]=-inf then exit(false) else exit(true);
  end;

function maxcost:longint;
  var i,j:longint;
  begin
    maxcost:=0;
    while spfa do
    begin
      i:=t;
      while i<>0 do
      begin
        j:=cur[i];
        dec(edge[j].flow);
        inc(edge[j xor 1].flow);
        i:=pre[i];
      end;
      ans:=ans+1;
      inc(maxcost,d[t]);
    end;
  end;

begin
  len:=-1;
  fillchar(p,sizeof(p),255);
  readln(a,b);
  t:=b*2+1;
  for i:=a to b do
  begin
    for j:=a to i-1 do
    begin
      k:=sqr(i)-sqr(j);
      if (sqrt(k)=trunc(sqrt(k))) and (gcd(trunc(sqrt(k)),j)=1) then
      begin
        add(i,j+b,1,i+j);
        add(j+b,i,0,-i-j);
        add(j,i+b,1,i+j);
        add(i+b,j,0,-i-j);
      end;
    end;
    add(0,i,1,0);
    add(i,0,0,0);
    add(i+b,t,1,0);
    add(t,i+b,0,0);
  end;
  k:=maxcost;
  writeln(ans div 2,' ',k div 2);
end.