差分约束系统小探（未完）

之前看听zyh讲了一下差分，没大懂；

后来稍微研究了一下，大概懂了一些；

这应该是线性规划的一种，大概是

给定一堆形如xj-xi<=wij的约束条件，要求我们满足条件的最优值（最大或最小）

整理一下这个式子，得到xi+wij>=xj 发现这个东西很像spfa中的三角不等式（松弛操作）

于是我们可以构造约束图，把xi看做点i

于是对于每一个xi+wij>=xj ，我们就连边i-->j边权为wij

然后做最短路即可

其实我还是不怎么懂，还需要在研究一下，待续

const inf=200000007;
type link=^node;
     node=record
       po,len:longint;
       next:link;
     end;

var w:array[0..1010] of link;
    count,d:array[0..1010] of longint;
    v:array[0..1010] of boolean;
    q:array[0..2000010] of longint;
    x,y,z,k1,k2,n,i:longint;

procedure add(x,y,z:longint);
  var p:link;
  begin
    new(p);
    p^.po:=y;
    p^.len:=z;
    p^.next:=w[x];
    w[x]:=p;
  end;

function spfa:longint;
  var x,i,y,f,r:longint;
      p:link;
  begin
    for i:=2 to n do
      d[i]:=inf;
    d[1]:=0;
    v[1]:=true;
    f:=1;
    r:=1;
    q[1]:=1;
    while f<=r do
    begin
      x:=q[f];
      v[x]:=false;
      p:=w[x];
      while p<>nil do
      begin
        y:=p^.po;
        if d[y]>d[x]+p^.len then
        begin
          d[y]:=d[x]+p^.len;
          if not v[y] then
          begin
            inc(r);
            q[r]:=y;
            v[y]:=true;
            inc(count[y]);
            if count[y]>n then exit(-1);
          end;
        end;
        p:=p^.next;
      end;
      inc(f);
    end;
    if d[n]=inf then exit(-2);
    exit(d[n]);
  end;

begin
  readln(n,k1,k2);
  for i:=1 to k1 do
  begin
    readln(x,y,z);
    add(x,y,z);
  end;
  for i:=1 to k2 do
  begin
    readln(x,y,z);
    add(y,x,-z);
  end;
  writeln(spfa);
end.