poj1011

这个贴代码容易理解一点：

var a:array[0..100] of longint;
    f:array[0..100] of boolean;
    s,i,p,j,n,max,k:longint;
    check:boolean;
function dfs(i,now,t:longint):boolean; //i当前用到了哪个木棒，now是拼接一根原木棒还差的长度，t为没用过的木棒总长度
  var j:integer;
  begin
    if now=0 then
    begin
      t:=t-p;
      if t=0 then exit(true);
      j:=1;
      while f[j] do j:=j+1;   //完成了一根原木棒的拼接后，找一根最大且没用过的木棒进行下一组拼接。
      f[j]:=true;
      if dfs(j+1,p-a[j],t) then exit(true);
      f[j]:=false;
      t:=t+p;                //回溯
    end
    else begin
      for j:=i to n do
      begin
        if (j>1) and (a[j]=a[j-1]) and not f[j-1] then continue;//剪枝，两根相等的木棒，前一根不能完成后续拼接那后                                                                   一根显然也不行
        if not f[j] and (now>=a[j]) then    //满足条件才尝试
        begin
          now:=now-a[j];
          f[j]:=true;
          if dfs(j,now,t) then exit(true);
          now:=now+a[j];     //回溯
          f[j]:=false;
          if a[j]=now then break;     // 此时后续尝试失败，所以当前状态不成立，直接返回一层（即使后面有和等于a[j]的
                                        一根或几根木棒，使用a[j]后剩下的木棒拼接肯定比使用几根和等于a[j]的木棒剩下
                                        的木棒拼接更灵活；使用木棒j不成立，显然后面的尝试也不成立，跳过！
        end;
      end;
    end;
    dfs:=false;            //所有尝试都试过了，显然当前状态不成立；
  end;

begin
  readln(n);
  while n<>0 do
  begin
    s:=0;
    fillchar(a,sizeof(a),0);
    max:=0;
    for i:=1 to n do
    begin
      read(a[i]);
      s:=s+a[i];
      if max<a[i] then max:=a[i];
    end;
    sort(1,n); //从大到小快排省略；
    readln;
    for i:=n downto 1 do                     //穷举原来可能有几根
      if (s mod i=0) and (s div i>=max) then //剪枝，原来长度一定是总长度的约数且不小于当前最长的小段
      begin
        fillchar(f,sizeof(f),false);
        p:=s div i;
        if dfs(1,p,s) then break;
      end;
    writeln(p);
    readln(n);
  end;
end.