bzoj3205

和bzoj2595类似，也是斯坦纳树

设f[l,r,]表示在点i机器人组合成了l-r最少推的次数，然后可得

f[l,r,i]=min(f[l,m,i]+f[m+1,r,i])

f[l,r,i]=min(f[l,r,j]+1) 点j能推到i

但是这样做肯定会TLE，考虑两个优化

首先，一开始其实有很多根本用不到，我们可以先从机器人初始位置搜下去，找到所有可以访问的点做dp即可

其次，观察第二个方程，它的边权都是1，我们一定要用spfa转移吗？不，我们可以用直接宽搜

具体的我们维护两个队列，第一个队列是初始的按从小到大排，新加入的点放在第二个队列，每次取两个队头小的那一个

但我还是tle，求神犇指教

const dx:array[1..4] of longint=(0,1,0,-1);
      dy:array[1..4] of longint=(1,0,-1,0);
      inf=1000000007;
type node=record
       x,y:longint;
     end;

var w:array[0..250010] of node;
    q1,q2,st:array[0..250010] of longint;
    po:array[0..501,0..501,1..4] of longint;
    f:array[0..250010,0..9,0..9] of longint;
    c:array[0..501,0..501] of char;
    v:array[0..250010] of boolean;
    loc:array[0..250010] of longint;
    next:array[0..250010,1..4] of longint;
    s:array[0..100010] of longint;
    mid,h1,t1,i,j,p,q,l,x,y,k,n,m,ans,mx,tot:longint;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

function dfs(x,y,k:longint):longint;
  var xx,yy:longint;
  begin
    if (po[x,y,k]=0) then exit(-1);
    if po[x,y,k]>0 then exit(po[x,y,k]);
    po[x,y,k]:=0;
    xx:=x+dx[k];
    yy:=y+dy[k];
    if (xx<1) or (xx>n) or (yy<1) or (yy>m) or (c[xx,yy]='x') then po[x,y,k]:=(x-1)*m+y
    else if c[xx,yy]='A' then po[x,y,k]:=dfs(xx,yy,(k+2) mod 4+1)
    else if c[xx,yy]='C' then po[x,y,k]:=dfs(xx,yy,k mod 4+1)
    else po[x,y,k]:=dfs(xx,yy,k);
    exit(po[x,y,k]);
  end;

function cmp(i,j,l,r:longint):boolean;
  begin
    exit(f[i,l,r]<f[j,l,r]);
  end;

procedure sort(l,r:longint);
  var i:longint;
  begin
    for i:=1 to mx do
      inc(s[i],s[i-1]);
    for i:=t1 downto 1 do
    begin
      q1[s[f[st[i],l,r]]]:=st[i];
      dec(s[f[st[i],l,r]]);
    end;
  end;

procedure bfs(l,r:longint);
  var h2,t2,i,x,y:longint;
  begin
    h2:=1;
    t2:=0;
    while (h2<=t2) or (h1<=t1) do
    begin
      if (h2>t2) or (h1<=t1) and cmp(q1[h1],q2[h2],l,r) then
      begin
        x:=q1[h1];
        inc(h1);
      end
      else begin
        x:=q2[h2];
        inc(h2);
      end;
      v[x]:=true;
      for i:=1 to 4 do
      begin
        if next[x,i]=0 then continue;
        y:=next[x,i];
        if not v[y] and (f[x,l,r]+1<f[y,l,r]) then
        begin
          v[y]:=true;
          f[y,l,r]:=f[x,l,r]+1;
          inc(t2);
          q2[t2]:=y;
        end;
      end;
    end;
  end;

begin
  readln(k,m,n);
  for i:=1 to n*m do
    for p:=1 to k do
      for q:=1 to k do
        f[i,p,q]:=inf;
  for i:=1 to n do
  begin
    for j:=1 to m do
    begin
      read(c[i,j]);
      if (c[i,j]>='1') and (c[i,j]<='9') then
      begin
        x:=ord(c[i,j])-48;
        inc(t1);
        w[t1].x:=i; w[t1].y:=j;
        f[t1,x,x]:=0;
        loc[(i-1)*m+j]:=t1;
      end;
    end;
    readln;
  end;
  fillchar(po,sizeof(po),255);
  h1:=1;
  while h1<=t1 do
  begin
    x:=w[h1].x; y:=w[h1].y;
    for i:=1 to 4 do
    begin
      if po[x,y,i]=-1 then
      begin
        po[x,y,i]:=dfs(x,y,i);
        if (po[x,y,i]>0) and (loc[po[x,y,i]]=0) then
        begin
          inc(t1);
          w[t1].x:=(po[x,y,i]-1) div m+1;
          w[t1].y:=(po[x,y,i]-1) mod m+1;
          loc[po[x,y,i]]:=t1;
        end;
      end;
      if po[x,y,i]>0 then next[h1,i]:=loc[po[x,y,i]];
    end;
    inc(h1);
  end;
  tot:=t1;
  for l:=1 to k do
    for p:=1 to k-l+1 do
    begin
      q:=p+l-1;
      h1:=1; t1:=0; mx:=0;
      for i:=1 to tot do
      begin
        v[i]:=false;
        for mid:=p to q-1 do
          f[i,p,q]:=min(f[i,p,q],f[i,p,mid]+f[i,mid+1,q]);
        if f[i,p,q]<inf then
        begin
          inc(t1);
          st[t1]:=i;
          inc(s[f[i,p,q]]);
          if f[i,p,q]>mx then mx:=f[i,p,q];
        end;
      end;
      sort(p,q);
      for i:=0 to mx do
        s[i]:=0;
      bfs(p,q);
    end;
  ans:=inf;
  for i:=1 to tot do
    ans:=min(ans,f[i,1,k]);
  if ans>=inf then writeln(-1)
  else writeln(ans);     
end.