bzoj2792

首先想到二分答案是吧，设为lim

这道题难在判定，我们先不管将一个数变为0的条件

先使序列满足相邻差<=lim,这个正着扫一遍反着扫一遍即可

然后我们就要处理将一个数变为0的修改代价

当i变为0后，我们分别考虑左右两边的代价，对于左边

如果a[j]>(i-j)*lim的话，aj要变成a[i]+(i-j)*lim，否则的话，对于k<=j都不用变化，右边类似的道理

观察式子，a[j]>(i-j)*lim即a[j]+j*lim>i*lim,怎么做很明显了吧……

var a,b,d:array[0..1000010] of longint;
    c,v:array[0..1000010] of int64;
    l,r,mx,mid,ans,i,n:longint;
    m,s:int64;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

function max(a,b:longint):longint;
  begin
    if a>b then exit(a) else exit(b);
  end;

function check(lim:longint):longint;
  var y,i:longint;
      s,w,t:int64;
  begin
    for i:=1 to n do
      b[i]:=a[i];
    t:=0;
    for i:=1 to n-1 do
      if b[i+1]>b[i]+lim then
      begin
        t:=t+b[i+1]-(b[i]+lim);
        b[i+1]:=b[i]+lim;
      end;
    for i:=n downto 2 do
      if b[i-1]>b[i]+lim then
      begin
        t:=t+b[i-1]-(b[i]+lim);
        b[i-1]:=b[i]+lim;
      end;
    if t>m then exit(0);
    fillchar(c,sizeof(c),0);
    fillchar(d,sizeof(d),0);
    for i:=1 to n do
    begin
      y:=min(i+b[i] div lim,n);
      c[y]:=c[y]+b[i]-int64(y-i)*int64(lim);
      inc(d[y]);
      if i<>1 then c[i-1]:=c[i-1]-b[i];
      dec(d[i]);
    end;
    s:=0;
    w:=0;
    for i:=n downto 1 do
    begin
      s:=s+c[i]+w*int64(lim);
      v[i]:=s;
      w:=w+d[i];
    end;
    fillchar(c,sizeof(c),0);
    fillchar(d,sizeof(d),0);
    for i:=n downto 1 do
    begin
      y:=max(i-b[i] div lim,1);
      c[y]:=c[y]+b[i]-int64(i-y)*int64(lim);
      inc(d[y]);
      c[i]:=c[i]-b[i];
      if i<>1 then dec(d[i-1]);
    end;
    s:=0;
    w:=0;
    for i:=1 to n do
    begin
      s:=s+c[i]+w*int64(lim);
      v[i]:=v[i]+s;
      w:=w+d[i];
    end;
    for i:=1 to n do
      if t+v[i]<=m then exit(i);

    exit(0);
  end;

begin
  readln(n,m);
  for i:=1 to n do
  begin
    read(a[i]);
    s:=s+a[i];
    if a[i]>mx then mx:=a[i];
  end;
  if s<=m then
  begin
    writeln('1 0');
    halt;
  end;
  l:=1;
  r:=mx;
  while l<=r do
  begin
    mid:=(l+r) shr 1;
    if check(mid)>0 then
    begin
      ans:=mid;
      r:=mid-1;
    end
    else l:=mid+1;
  end;
  writeln(check(ans),' ',ans);
end.