bzoj1064

很巧妙的题

首先有几种情况

1. 有环 2.两点间有多条路径 3.其他

3.显然最简单，最小是3，最大是每个弱联通块中最长链

2.显然，两点间两条路径的差是答案的倍数

1.出现环，那答案一定是其约数，那么最大答案就是所有环长的最大公约数，最小是最大的大于等于3的最小因数

综合以上，我们就有了大概的思路，但是不好处理

有一个精妙的做法，对于每条边添加一个长度为-1的反向边，一下就简单多了

type node=record
       po,next,num:longint;
     end;

var e:array[0..4000010] of node;
    p,d:array[0..200010] of longint;
    v:array[0..200010] of boolean;
    mi,i,l,r,n,m,len,ans,x,y:longint;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

function max(a,b:longint):longint;
  begin
    if a>b then exit(a) else exit(b);
  end;

function gcd(a,b:longint):longint;
  begin
    if b=0 then exit(a)
    else exit(gcd(b,a mod b));
  end;

procedure add(x,y,z:longint);
  begin
    inc(len);
    e[len].po:=y;
    e[len].num:=z;
    e[len].next:=p[x];
    p[x]:=len;
  end;

procedure dfs(x:longint);
  var i,y:longint;
  begin
    v[x]:=true;
    i:=p[x];
    while i<>-1 do
    begin
      y:=e[i].po;
      if v[y] then ans:=gcd(ans,abs(d[x]+e[i].num-d[y]))
      else begin
        d[y]:=d[x]+e[i].num;
        dfs(y);
      end;
      i:=e[i].next;
    end;
  end;

procedure find(x:longint);
  var i,y:longint;
  begin
    v[x]:=true;
    l:=min(l,d[x]);
    r:=max(r,d[x]);
    i:=p[x];
    while i<>-1 do
    begin
      y:=e[i].po;
      if not v[y] then
      begin
        d[y]:=d[x]+e[i].num;
        find(y);
      end;
      i:=e[i].next;
    end;
  end;

begin
  len:=-1;
  fillchar(p,sizeof(p),255);
  readln(n,m);
  for i:=1 to m do
  begin
    readln(x,y);
    add(x,y,1);
    add(y,x,-1);
  end;
  for i:=1 to n do
    if not v[i] then dfs(i);
  if ans<>0 then
  begin
    mi:=ans;
    for i:=3 to ans do
      if ans mod i=0 then
      begin
        mi:=i;
        break;
      end;
  end
  else begin
    fillchar(v,sizeof(v),false);
    for i:=1 to n do
      if not v[i] then
      begin
        d[i]:=0;
        l:=0;  r:=0;
        find(i);
        ans:=ans+r-l+1;
      end;

    mi:=3;
  end;
  if ans<3 then writeln('-1 -1') else writeln(ans,' ',mi);
end.