BZOJ1030 [JSOI2007]文本生成器

搬运以前的题解中：

此题一看60个模式串，就知道是AC自动机。

最后要求含有模式串的个数，也就是（全部的个数 - 不含模式串的个数）。

于是就是裸的AC自动机上做DP了，再一看，m <= 100, 真是良心题，还不用矩阵优化。

这里有一个trick：在建自动机的时候要搞清楚哪些状态是无效的，我忘了加一句话（line 51）然后WA了两次。。。

 

于是开始复习（重新学习）AC自动机。。。各种悲剧。。。总算A掉了

 

const
  prime : longint = 10007;
 
var
  q, fai : array[0..10000] of longint;
  tail : array[0..10000] of boolean;
  tr : array[0..7000, 0..30] of longint;
  f : array[0..110, 0..6100] of longint;
  i, n, m, tot, len, j, ans, sum : longint;
  st : string;
 
procedure make_trie;
var
  p, x, i : longint;
 
begin
  p := 1;
  for i := 1 to len do begin
    x := ord(st[i]) - ord('A') + 1;
    if tr[p, x] = 0 then begin
      inc(tot);
      tr[p, x] := tot;
    end;
    if tail[p] then tail[tr[p, x]] := true;
    p := tr[p, x];
  end;
  tail[p] := true;
end;
 
procedure make_acmach;
var
  h, t, i, x, x1, y : longint;
 
begin
  q[1] := 1;
  fai[1] := 0;
  h := 1;
  t := 1;
  while h <= t do begin
    x := q[h];
    inc(h);
    for i := 1 to 26 do begin
      y := tr[x, i];
      if y > 0 then begin
        inc(t);
        q[t] := y;
        x1 := fai[x];
        while true do begin
          if tr[x1, i] > 0 then begin
            fai[y] := tr[x1, i];
            if tail[tr[x1, i]] then tail[tr[x, i]] := true;
            break
          end;
          x1 := fai[x1];
        end;
      end;
    end;
  end;
end;
 
procedure dp(t : longint);
var
  i, j, x : longint;
 
begin
  for i := 1 to tot do begin
    if tail[i] then continue;
    for j := 1 to 26 do begin
      x := i;
      while true do begin
        if tr[x, j] > 0 then begin
          f[t, tr[x, j]] := (f[t, tr[x, j]] + f[t - 1, i]) mod prime;
          break;
        end;
        x := fai[x];
      end;
    end;
  end;
end;
 
begin
  readln(n, m);
  tot := 1;
  fillchar(tail, sizeof(tail), false);
  fillchar(tr, sizeof(tr), 0);
  for i := 1 to 26 do tr[0, i] := 1;
  for i := 1 to n do begin
    readln(st);
    len := length(st);
    make_trie;
  end;
  make_acmach;
  sum := 1;
  for i := 1 to m do
    sum := (sum * 26) mod prime;
  f[0, 1] := 1;
  for i := 1 to m do
    dp(i);
  for i := 1 to tot do
    if not tail[i] then ans := (ans + f[m, i]) mod prime;
  writeln((sum - ans + prime) mod prime);
end.