Arrange m3u8 1.0

main.bat

@echo off
color 0a
title Arrange m3u8 1.0

SETLOCAL ENABLEEXTENSIONS
SETLOCAL ENABLEDELAYEDEXPANSION

set PARAM=%~1
set FILE_EXT=.m3u8

if "%PARAM%" equ "" (
    echo Please drag and drop a ^'*%FILE_EXT%' file onto this batch program.
    goto NORMAL_EXIT
)

set FILE_NAME=
set SAVE_DIR=

for %%i in ("%PARAM%") do (
    if /i "%%~xi" neq "%FILE_EXT%" (
        echo Type of file must be ^'%FILE_EXT%'.
        goto NORMAL_EXIT
    )
    if /i %%~zi equ 0 (
        echo Error #1
        goto NORMAL_EXIT
    )
    pushd "%%~dpi"
    set T_STR=%%~ni
    if /i "!T_STR:~-3!" neq ".ts" (
        echo Error #2
        goto NORMAL_EXIT
    )
    set SAVE_DIR=!T_STR:~0,-3!
    if "!SAVE_DIR!" equ "" (
        echo Error #3
        goto NORMAL_EXIT
    )
    if not exist "!SAVE_DIR!" mkdir "!SAVE_DIR!"
    set FILE_NAME=%%~nxi
)
for /f "usebackq eol=# tokens=1* delims=?" %%i in ("%FILE_NAME%") do (
    if exist "%%i" move "%%i" "%SAVE_DIR%"
)

move "%FILE_NAME%" "%SAVE_DIR%"

:NORMAL_EXIT
popd
pause
exit

附件1