Excel-DNA项目只用1个文件实现Ribbon CustomUI和CustomTaskpane定制【VB.Net版】

Excel-DNA项目中的自定义功能区和自定义任务窗格需要用到各种命名空间、添加所需文件，才能实现。后来我发现可以把所有代码都写在Class1.vb这个默认文件中。

大家可以在Visual Studio中创建一个类库项目（.Net Framework），然后把默认的Class1.vb中的代码整体替换为下面我贴的这个代码。然后启动调试，就可以看到自定义功能区和任务窗格了。

Imports System.Runtime.InteropServices
Imports ExcelDna.Integration
Imports ExcelDna.Integration.CustomUI
Imports Excel = Microsoft.Office.Interop.Excel
<ComVisible(True)>
Public Class Class1
    Inherits ExcelRibbon
    Implements IExcelAddIn
    Public R As IRibbonUI
    Public Overrides Function GetCustomUI(RibbonID As String) As String
        Dim xml As XElement
        xml = <customUI xmlns="http://schemas.microsoft.com/office/2009/07/customui" onLoad="OnLoad">
                  <ribbon startFromScratch="false">
                      <tabs>
                          <tab id="Tab1" label="RibbonXmlEditor">
                              <group id="Group1" label="Author:ryueifu">
                                  <button id="Button1" label="CTP" imageMso="C" onAction="Button1_Click"/>
                                  <button id="Button2" label="UnLoad" imageMso="U" onAction="Button2_Click"/>
                              </group>
                          </tab>
                      </tabs>
                  </ribbon>
              </customUI>
        Return xml.ToString()
    End Function
    Public Sub OnLoad(ribbon As IRibbonUI)
        R = ribbon
        R.ActivateTab(ControlID:="Tab1")
    End Sub
    Public Sub Button1_Click(control As IRibbonControl)
        ctp.Visible = Not ctp.Visible
    End Sub
    Public Sub Button2_Click(control As IRibbonControl)
        Dim ThisAddin As Excel.AddIn
        ThisAddin = ExcelDnaUtil.Application.AddIns.Item(Index:=My.Application.Info.AssemblyName)
        ThisAddin.Installed = False
    End Sub

    Public Sub AutoOpen() Implements IExcelAddIn.AutoOpen
        Module1.CreateCTP()
    End Sub

    Public Sub AutoClose() Implements IExcelAddIn.AutoClose
        Module1.DisposeCTP()
    End Sub
End Class

Public Module Module1
    Public uc As System.Windows.Forms.UserControl
    Public ctp As CustomTaskPane
    Public Sub CreateCTP()
        uc = New Windows.Forms.UserControl
        ctp = CustomTaskPaneFactory.CreateCustomTaskPane(userControl:=uc, title:="CTP")
        With ctp
            .DockPosition = MsoCTPDockPosition.msoCTPDockPositionRight
            .Visible = True
        End With
    End Sub
    Public Sub DisposeCTP()
        ctp.Dispose()
    End Sub
End Module