delphi 参数化sql

曾经查过资料，后来忘了，现在做一下记录。

---------

在 sql 语句里占位使用 一个冒号和一个用来表示这个位置的符号, 例如：SELECT * FROM aTableName WHERE aCol =  :ColVal

SELECT * FROM aTableName WHERE aCol =  :ColVal

对占位了的地方赋值这里使用的是 paremeters 属性的 paramByName 作的, 例如：

LDataSet.Parameters.ParamByName('ColVal').Value := 'SomeValue';

---------

最近在 Delphi 7 中通过参数化的方式存汉字字符串，出现只存入了一部分的情况，搜索资料并测试之后，发现设置 DataType = ftWideString 可以解决。

示例：

LCommand.Parameters.ParamByName('AKeyName').DataType := ftWideString;
LCommand.Parameters.ParamByName('AKeyName').Value := '我没有，我不是，别瞎说';

DataType 的类型：DB.pas/TFieldType

--date=2019-08-16

---------

为了使贴出来的代码具有完成性和尽量的简单性, 把以前的代码改写了一下, 现在的代码是控制台程序,

在程序体中对数据库访问代码作了简单的调用.

---------

今天重新看了一遍代码，发现一个问题，就是 程序入口里的变量 QueryResult 所使用过的对象都没有释放！！！

--date=2019-09-11

---------

数据访问单元的代码：

unit uDBAccesser;

interface

uses
  System.Generics.Collections, Data.Win.ADODB;


type TTAbleInfo = record
  DataSource : String;
  DbName     : String;
  Username   : String;
  Password   : String;
  Name       : String;
  IntCol     : String;
  TxtCol     : String;
end;

type TEntity = record
  SomeInt : Integer;
  SomeTxt : String;
end;

type TDBAccesser = class
  private
    FConn : TADOConnection;

    function Query( const ASql : String; const AParams : TDictionary<String, Variant>) : TList<TEntity>;
    // 广泛含义的更新
    function Update(Const ASql : String; const AParams : TDictionary<String, Variant>) : Boolean; overload;
  public
    constructor Create();
    destructor  Destroy(); override;

    function QueryAll() : TList<TEntity>;
    function QueryByInt(const AInt : Integer) : TList<TEntity>;
    function QueryByTxt(const ATxt : String ) : TList<TEntity>;
    function InsertOne(const AEntity : TEntity) : Boolean;
    function Delete(const AEntity : TEntity) : Boolean;
    // 狭义的更新
    function Update(const AOldValue : TEntity; const ANewValue : TEntity) : Boolean; overload;
end;


var
  TableInfo : TTableInfo;

implementation

uses
  System.SysUtils, System.Variants, Winapi.ActiveX;


constructor TDBAccesser.Create();
const  // MS SQL
  LConnStrFormat : String = 'provider=SQLOLEDB.1;password=%s;User ID=%s;'
                          + 'Initial CataLog=%s;Data source=%s;';
var
  LConnStr : String;
begin
  try
    LConnStr := Format(LConnStrFormat, [TableInfo.Password, TableInfo.Username,
                                        TableInfo.DbName, TableInfo.DataSource]);

    Self.FConn := TADOConnection.Create(nil);
    Self.FConn.ConnectionString := LConnStr;
    Self.FConn.LoginPrompt := False;
    Self.FConn.Connected   := True;
  except
    on Err : Exception do begin
      FreeAndNil(Self.FConn);
      WriteLn('Error on create DBAccesser: ' + Err.Message);
    end;
  end;
end;

destructor TDBAccesser.Destroy;
begin
  FreeAndNil(Self.FConn);
end;


function TDBAccesser.Query(const ASql: string; const AParams: TDictionary<System.string,System.Variant>) : TList<TEntity>;
var
  LDataSet : TADODataSet;
  LRow : TEntity;
  LKey : String;
begin
  LDataSet := nil;
  try
    LDataSet := TADODataSet.Create(nil);
    LDataSet.Connection  := Self.FConn;
    LDataSet.CommandText := ASql;

    // 我印象有篇文章说这句必须要有, 但不写也没发现问题
    LDataSet.Parameters.ParseSQL(LDataSet.CommandText, True);
    if (AParams <> nil) then begin
      for LKey in AParams.Keys do begin
        LDataSet.Parameters.ParamByName(LKey).Value := AParams.Items[LKey];
      end;
    end;

    LDataSet.Open;
    LDataSet.First;

    Result := TList<TEntity>.Create();
    while not LDataSet.Eof do begin
      LRow.SomeInt := LDataSet.FieldByName(TableInfo.IntCol).AsInteger; // 也可以这种格式 LDataSet.Fields[0].AsBoolean;
      LRow.SomeTxt := LDataSet.FieldByName(TableInfo.TxtCol).AsString;

      Result.Add(LRow);

      LDataSet.Next;
    end;
  finally
    FreeAndNil(LDataSet);
  end;
end;

function TDBAccesser.Update(Const ASql : String; const AParams : TDictionary<String, Variant>) : Boolean;
var
  LCmd : TADOCommand;
  LKey : String;
  LRowsAffected : Integer;
begin
  Result := False;
  LCmd := nil;
  try
    LCmd := TADOCommand.Create(nil);
    LCmd.Connection  := Self.FConn;
    LCmd.CommandText := ASql;

    LCmd.Parameters.ParseSQL(LCmd.CommandText, True);

    if (AParams <> nil) then begin
      for LKey in AParams.Keys do begin
        LCmd.Parameters.ParamByName(LKey).Value := AParams.Items[LKey];
      end;
    end;

    // 也可以直接在 EmptyParam 的位置直接写 [Param1, Param2, ...] 格式的内容，
    // 而不使用上面的 Parameters，两者不能同时使用，
    // 但具体什么情况我也忘了，相应代码也找不到了，要想知道真实情况，还得再动手去摸索
    LCmd.Execute(LRowsAffected, EmptyParam);

    if (LRowsAffected > 0) then begin
      Result := True;
    end
    else begin
      Result := False;
    end;
  finally
    FreeAndNil(LCmd);
  end;
end;


function TDBAccesser.QueryAll() : TList<TEntity>;
const
  LSqlFormat : String = 'SELECT %s, %s FROM %s';
var
  LSql : String;
begin
  LSql := Format(LSqlFormat, [TableInfo.TxtCol, TableInfo.IntCol, TableInfo.Name]);

  Result := Self.Query(LSql, nil);
end;

function TDBAccesser.QueryByInt(const AInt: Integer) : TList<TEntity>;
const
  LSqlFormat : String = 'SELECT %s, %s FROM %s WHERE %s = :$Int ';
var
  LSql : String;
  LParams : TDictionary<String, Variant>;
begin
  LParams := TDictionary<String, Variant>.Create();
  try
    LSql := Format(LSqlFormat, [TableInfo.TxtCol, TableInfo.IntCol,
                                TableInfo.Name, TableInfo.IntCol]);

    LParams.Add('$Int', AInt);

    Result := Self.Query(LSql, LParams);
  finally
    FreeAndNil(LParams);
  end;
end;

function TDBAccesser.QueryByTxt(const ATxt: String) : TList<TEntity>;
const
  LSqlFormat : String = 'SELECT %s, %s FROM %s WHERE %s = :$Txt ';
var
  LSql : String;
  LParams : TDictionary<String, Variant>;
begin
  LParams := TDictionary<String, Variant>.Create();
  try
    LSql := Format(LSqlFormat, [TableInfo.TxtCol, TableInfo.IntCol,
                                TableInfo.Name, TableInfo.TxtCol]);

    LParams.Add('$Txt', ATxt);

    Result := Self.Query(LSql, LParams);
  finally
    FreeAndNil(LParams);
  end;
end;

function TDBAccesser.InsertOne(const AEntity: TEntity) : Boolean;
const
  LSqlFormat : String = 'INSERT INTO %s (%s, %s) '
                      + 'VALUES (:$Txt, :$Int) ';
var
  LSql : String;
  LParams : TDictionary<String, Variant>;
begin
  LParams := TDictionary<String, Variant>.Create();
  try
    LSql := Format(LSqlFormat, [TableInfo.Name, TableInfo.TxtCol, TableInfo.IntCol]);

    LParams.Add('$Txt', AEntity.SomeTxt);
    LParams.Add('$Int', AEntity.SomeInt);

    Result := Self.Update(LSql, LParams);
  finally
    FreeAndNil(LParams);
  end;
end;

function TDBAccesser.Delete(const AEntity: TEntity) : Boolean;
const
  LSqlFormat : String = 'DELETE FROM %s '
                      + 'WHERE %s = :$Txt AND %s = :$Int ';
var
  LSql : String;
  LParams : TDictionary<String, Variant>;
begin
  LParams := TDictionary<String, Variant>.Create();
  try
    LSql := Format(LSqlFormat, [TableInfo.Name, TableInfo.TxtCol, TableInfo.IntCol]);

    LParams.Add('$Txt', AEntity.SomeTxt);
    LParams.Add('$Int', AEntity.SomeInt);

    Result := Self.Update(LSql, LParams);
  finally
    FreeAndNil(LParams);
  end;
end;

function TDBAccesser.Update(const AOldValue: TEntity; const ANewValue: TEntity) : Boolean;
const
  LSqlFormat : String = 'UPDATE %s '
                      + 'SET %s = :$TxtVal, %s = :$IntVal '
                      + 'WHERE %s = :$OldTxtVal AND %s = :$OldIntVal ';
var
  LSql : String;
  LParams : TDictionary<String, Variant>;
begin
  LParams := TDictionary<String, Variant>.Create();
  try
    LSql := Format(LSqlFormat, [TableInfo.Name,
                                TableInfo.TxtCol, TableInfo.IntCol,
                                TableInfo.TxtCol, TableInfo.IntCol]);

    LParams.Add('$TxtVal', ANewValue.SomeTxt);
    LParams.Add('$IntVal', ANewValue.SomeInt);

    LParams.Add('$OldTxtVal', AOldValue.SomeTxt);
    LParams.Add('$OldIntVal', AOldValue.SomeInt);

    Result := Self.Update(LSql, LParams);
  finally
    FreeAndNil(LParams);
  end;
end;


initialization
  TableInfo.DataSource := '.';
  TableInfo.DbName     := 'simpleTestByX';
  TableInfo.Username   := 'sa';
  TableInfo.Password   := '123456';
  TableInfo.Name       := 'tab_simple_test';
  TableInfo.IntCol     := 'some_int';
  TableInfo.TxtCol     := 'some_txt';

  CoInitialize(nil);

finalization
  CoUninitialize();


end.

控制台程序入口代码，对上面的单元进行简单的调用：

program ProjectParameterizedSql;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils,
  System.Generics.Collections,
  uDBAccesser in 'uDBAccesser.pas';


function FormatEntity(AEntity : TEntity) : String;
begin
  Result := Format(' SomeInt = %d, SomeTxt = %s ', [AEntity.SomeInt, AEntity.SomeTxt]);
end;


var
  DBAccesser      : TDBAccesser;
  EntityQuery     : TEntity;
  EntityInsert    : TEntity;
  EntityDelete    : TEntity;
  EntityUpdateNew : TEntity;
  EntityUpdateOld : TEntity;
  EntityCommon    : TEntity;
  QueryResult     : TList<TEntity>;
begin
  try
    DBAccesser := TDBAccesser.Create();
    try
      WriteLn('1) insert one: ');

      EntityInsert.SomeInt := 1;
      EntityInsert.SomeTxt := 'Hello';
      WriteLn('  entity = ', FormatEntity(EntityInsert));

      WriteLn('  insert success? ', DBAccesser.InsertOne(EntityInsert));
      WriteLn('----------------');

      WriteLn('2) query all: ');

      QueryResult := DBAccesser.QueryAll();

      WriteLn('  total = ', QueryResult.Count);
      for EntityCommon in QueryResult do begin
        WriteLn('  ', FormatEntity(EntityCommon));
      end;
      WriteLn('----------------');

      WriteLn('3) update: ');

      EntityUpdateOld := EntityInsert;
      EntityUpdateNew.SomeInt := 2;
      EntityUpdateNew.SomeTxt := 'World';

      WriteLn('  old : ', FormatEntity(EntityUpdateOld));
      WriteLn('  new : ', FormatEntity(EntityUpdateNew));

      WriteLn('  update success? ', DBAccesser.Update(EntityUpdateOld, EntityUpdateNew));
      WriteLn('----------------');

      WriteLn('4) query by int:');

      EntityQuery := EntityUpdateNew;
      WriteLn('  int = ', EntityQuery.SomeInt);

      QueryResult := DBAccesser.QueryByInt(EntityQuery.SomeInt);

      WriteLn('  total : ', QueryResult.Count);
      for EntityCommon in QueryResult do begin
        WriteLn('  ', FormatEntity(EntityCommon));
      end;
      WriteLn('----------------');

      WriteLn('5) query by txt:');

      EntityQuery := EntityUpdateNew;
      WriteLn('  txt = ', EntityQuery.SomeTxt);

      QueryResult := DBAccesser.QueryByTxt(EntityQuery.SomeTxt);

      WriteLn('  total : ', QueryResult.Count);
      for EntityCommon in QueryResult do begin
        WriteLn('  ', FormatEntity(EntityCommon));
      end;
      WriteLn('----------------');

      WriteLn('6) delete:');

      EntityDelete := EntityUpdateNew;
      WriteLn('  entity = ', FormatEntity(EntityDelete));

      WriteLn('  delete success? ', DBAccesser.Delete(EntityDelete));
      WriteLn('----------------');

      WriteLn('7) query all: ');

      QueryResult := DBAccesser.QueryAll();
      WriteLn('  total : ', QueryResult.Count);
      for EntityCommon in QueryResult do begin
        WriteLn('  ', FormatEntity(EntityCommon));
      end;
      WriteLn('----------------');

      WriteLn('--- THE END ---');
    finally
      FreeAndNil(DBAccesser);
    end;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  ReadLn;
end.

--------- THE END ---------