DisneyDiffuse解析

我们知道Unity默认的StandardShader用的漫反射是DisneyDiffuse，那么DisneyDiffuse和传统的Lambert相比究竟有什么不同呢？今天我们就来看一看：

首先Lambert公式就不多说了（n*l）

DisneyDiffuse公式是这样的：

fd90 = 0.5 + 2*ldoth * ldoth* _Roughness
disneyDiffuse = (1 + (fd90 - 1) * pow5(1 - ndotl)) * (1 + (fd90 - 1) * pow5(1 - ndotv))

首先我们看fd90(漫反射在法线和视线夹角90度的情况下的反射率)是怎么算的：

首先是0.5作为一个基础值，后面的附加值主要由两部分构成，一个是ldoth，一个是粗糙度，通过这个公式我们可以看出当光线l和半角向量h的夹角（也就是和视线的夹角）越来越小，反射率会越来越大；同时，如果粗糙度越来越大，反射率也会越来越大。

然后是disneyDiffuse的计算，主要由两个因子相乘，一个是1 + (fd90 -1)*pow5(1-ndotl),这一项其实就是算正常应该反射的强度1加上反射率超出1的部分和（1-nl）的指数运算，翻译过来就是如果fd90>1，则随着ndotl越小，这个因子的值越大。第二个因子也是一样，只是把nl换成了nv，翻译过来就是如果fd90>1，则随着ndotv越小，因子的值越大。

两个因子合并起来就是当fd90>1时，随着法线和光线的角度以及法线和视线的角度越来越大，反射率就越来越大。而fd90是根据视线和光线的角度变小而增大，综上就可以总结出DisneyDiffuse主要考虑了漫反射在当视线和光线角度比较小的时候，粗糙度大的表面会反射到更多的光到视野的现象，随着光线、视线和法线的夹角趋近90度，该现象就会越来越明显。

而兰伯特光照模型是完全没有考虑到粗糙度对于漫反射的影响，所以具体使用哪种光照模型还是看大家对于效果和效率的一个权衡。

DisneyDiffuse代码如下：

Shader "Unlit/DisneyDiffuse"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _Roughness("Roughness",Range(0,1)) = 0.5
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            #define PI 3.1415926
            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
                float3 normal:NORMAL;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
                float3 normalWS:TEXCOORD1;
                float3 positionWS:TEXCOORD2;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            float _Roughness;
            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                o.normalWS = UnityObjectToWorldNormal(v.normal);
                o.positionWS = mul(unity_ObjectToWorld, v.vertex);
                return o;
            }

            float pow5(float a) {
                return a * a * a * a * a;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                float3 worldNormal = normalize(i.normalWS);
                float3 worldViewDir = normalize(UnityWorldSpaceViewDir(i.positionWS));
                float3 lightDir = _WorldSpaceLightPos0.xyz;

                float ndotl = dot(worldNormal, lightDir);
                float halfDir = normalize(lightDir + worldViewDir);
                float ndotv = dot(worldNormal, worldViewDir);
                float ldoth = dot(lightDir, halfDir);

                float fd90 = 0.5 + 2*ldoth * ldoth* _Roughness;
                float disneyDiffuse = (1 + (fd90 - 1) * pow5(1 - ndotl)) * (1 + (fd90 - 1) * pow5(1 - ndotv));
                
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv)* disneyDiffuse/PI*saturate(ndotl);
                return col;
            }
            ENDCG
        }
    }
}

效果对比如下（上面的球是兰伯特，下面的球是DisneyDiffuse，其实看起来差别没多大）：