ClientDataSet中动态添加计算字段并用计算字段显示记录的UpdateStatus

ClientDataSet中每条记录都有UpdateStatus=(usUnmodified, usModified, usInserted, usDeleted)记录该条数据是修改的，删除的，还是新增的等。有时候我们只想看修改的或新增的或删除的就可能用到这一属性。下图用计算字段显示UpdateStatus状态。

***************************************************************************************************************************

具体操作:

***************************************************************************************************************************

DBGrid1.DataSource->DataSource1.DataSet->ClientDataSet1.ProviderName->DataSetProvider1.DataSet->

SQLDataset1.SQLConnection->SQLConnection1具体数据库(这里连接的是oracle中的PERSONS表);

SQLDataSet1.CommandText:=SELECT * PERSONS;ClientDataSet1.Active:=true;

DBNavigator1.DataSource->DataSource1。

***************************************************************************************************************************

主要代码:

***************************************************************************************************************************

用到了GetEnumName方法要uses TypInfo单元.

procedure TForm3.Button1Click(Sender: TObject);
var
  I: integer;
  Field: TField;
begin
  ClientDataSet1.Close;
  SQLDataSet1.Active := true;
  ClientDataSet1.Fields.Clear;
  for I := 0 to SQLDataSet1.FieldCount - 1 do
  begin
    Field := SQLDataSet1.Fields.Fields[I];
    if Field.DataType = ftWideString then
    begin
      with TWideStringField.Create(self) do
      begin
        Name := Field.Name;
        FieldName := Field.FieldName;
        FieldKind := Field.FieldKind;
        DataSet := ClientDataSet1;
      end;
    end
    else if Field.DataType = ftFMTBcd then
    begin
      with TFMTBcdField.Create(self) do
      begin
        Name := Field.Name;
        FieldName := Field.FieldName;
        FieldKind := Field.FieldKind;
        DataSet := ClientDataSet1;
      end;
    end;
  end;
  // 添加计算字段
  with TWideStringField.Create(self) do
  begin
    Name := 'UpdateStatus';
    FieldName := 'UpdateStatus';
    FieldKind := fkCalculated;
    DataSet := ClientDataSet1;
  end;
  ClientDataSet1.FieldDefs.Update;
  ClientDataSet1.Open;
end;

procedure TForm3.ClientDataSet1CalcFields(DataSet: TDataSet);
begin
ClientDataSet1.FieldByName('UpdateStatus').AsString :=
    GetEnumName(TypeInfo(TUpdateStatus), Ord(ClientDataSet1.UpdateStatus));
end;

ClientDataSet1CalcFields连接到ClientDataSet1.OnCalcFields事件。

注意:一旦调用了ApplyUpdates方法或MergeChangeLog就会被重置为usUnmodified状态。