SICP_2.67-2.72

#lang racket

(define (make-leaf symbol weight)
  (list 'leaf symbol weight))

(define (leaf? object)
  (eq? (car object) 'leaf))

(define (symbol-leaf x) (cadr x))
(define (weight-leaf x) (caddr x))

(define (make-code-tree left right)
  (list left
        right
        (append (symbols left) (symbols right))
        (+ (weight left) (weight right))))

(define (left-branch tree) (car tree))
(define (right-branch tree) (cadr tree))

(define (symbols tree)
  (if (leaf? tree)
      (list (symbol-leaf tree))
      (caddr tree)))

(define (weight tree)
  (if (leaf? tree)
      (weight-leaf tree)
      (cadddr tree)))

;;;;;;;;;解码
(define (decode bits tree)
  (define (decode-1 bits current-branch)
    (if (null? bits)
        '()
        (let ((next-branch
               (choose-branch (car bits) current-branch)))
          (if (leaf? next-branch)
              (cons (symbol-leaf next-branch)
                    (decode-1 (cdr bits) tree))
              (decode-1 (cdr bits) next-branch)))))
  (decode-1 bits tree))

(define (choose-branch bit branch)
  (cond ((= bit 0) (left-branch branch))
        ((= bit 1) (right-branch branch))
        (else (error "bad bit --CHOOSE-BRANCH" bit))))


;;;;;;;;带权重的元素集合
(define (adjoin-set x set)
  (cond ((null? set) (list x))
  ((< (weight x) (weight (car set))) (cons x set))
  (else (cons (car set) (adjoin-set x (cdr set))))))

(define (make-leaf-set pairs)
  (if (null? pairs)
      '()
      (let ((pair (car pairs)))
        (adjoin-set (make-leaf (car pair)
                               (cadr pair))
                    (make-leaf-set (cdr pairs))))))

;;;;;;;;;;;;;2.67
(define sample-tree
  (make-code-tree (make-leaf 'A 4)
                  (make-code-tree
                   (make-leaf 'B 2)
                   (make-code-tree (make-leaf 'D 1)
                                   (make-leaf 'C 1)))))

(define sample-message '(0 1 1 0 0 1 0 1 0 1 1 1 0))

;sample-tree
;(decode sample-message sample-tree)

;;;;;;;;;;;2.68
(define (encode message tree)
  (if (null? message)
      '()
      (append (encode-symbol (car message) tree)
              (encode (cdr message) tree))))

(define (encode-symbol symbol tree)
  (cond ((not (have? symbol tree))
        (error "false symbol" symbol))
        ((leaf? tree) '())
        ((have? symbol (left-branch tree))
         (cons 0 (encode-symbol symbol (left-branch tree))))
        ((have? symbol (right-branch tree))
         (cons 1 (encode-symbol symbol (right-branch tree))))))

(define (have? symbol tree)
  (if (leaf? tree)
      (eq? (symbol-leaf tree) symbol)
      (tree-have? symbol (symbols tree))))

(define (tree-have? symbol set)
  (cond ((null? set) false)
        ((eq? symbol (car set)) true)
        (else (tree-have? symbol (cdr set)))))


;;;;;;;;;;;;;;test
;(encode '(A D A B B C A) sample-tree)

;;;;;;;;;;;;;;2.69
(define (generate-huffman-tree pairs)
  (successive-merge (make-leaf-set pairs)))

(define (successive-merge leaf-set)
  (cond ((= 0 (length leaf-set)) '())
        ((= 1 (length leaf-set)) (car leaf-set))
        (else (let ((sub (make-code-tree (car leaf-set)
                                         (cadr leaf-set)))
                    (rem (cddr leaf-set)))
                (successive-merge (adjoin-set sub rem))))))

;(define (successive-merge2 leaf-set)
 ; (if (null? (cdr leaf-set))
  ;    (car leaf-set)
   ;   (make-code-tree (car leaf-set) (successive-merge (cdr leaf-set)))))

(define pairs '((A 4) (B 2) (C 1) (D 1)))

;(generate-huffman-tree pairs)


;;;;;;;;;;;;;2.70
(define rock-tree (generate-huffman-tree '((boom 1) (Wah 1) (a 2)
                                                   (Get 2) (job 2)
                                                   (Sha 3) (yip 9) (na 16))))


(define rock-message '(Get a job
                           Sha na na na na na na na na
                           Get a job
                           Sha na na na na na na na na
                           Wah yip yip yip yip yip yip yip yip yip
                           Sha boom))

(length (encode rock-message rock-tree))
;(encode rock-message rock-tree)
;不定长需要84位
;定长需要108位

;;;;;;;;;;;2.71
(define pairsn5 '((a 1) (b 2) (c 4) (d 8) (e 16)))
(define pairsn10 '((a 1) (b 2) (c 4) (d 8) (e 16) (f 32) (g 64)
                         (h 128) (i 256) (j 512)))

(generate-huffman-tree pairsn5)
(generate-huffman-tree pairsn10)
;;;;;;;;;;n=5 时最小的要用4位，最大要用1位
;;;;;;;;;;n=10 时最小用用9位，最大用1位

;;;;;;;;;;;;;2.72

对于2.69 首先要有清晰的思路，不然就会写出注释掉的那种不明觉厉的东西

1.当leaf-set为空集时返回空集

2.当leaf-set只有一个元素时表示所有元素已经组合成了一棵哈夫曼树

3.不断重复，取出最小的两个权重的叶子或树构成一棵新树(由于make-leaf-set 中有adjoin-set 过程，所以最小的和次小权重的树或叶子都会放在头部)

然后并到剩下的集合中

另外:对于检查一个list是否为空集还可以利用length

对于2.72：

一种符号的步长分析可得 n=一个符号的二进制位数*符号出现的频数

（一个符号二进制位数对应append过程）

一个符号出现的二进制位数还涉及encode-symbol过程，由于要考虑检查符号在不在集合中，所以n=encode-symbol的步数*符号出现频数

注意题目是说  一个  符号，所以不用考虑符号出现的频数，也不用考虑append过程了，剩下的就是encode-symbol的步数

对于频数最大的一定会在哈夫曼树第n-1（根为n层）层，所以二进制位数为1，由我写的encode-symbol过程，检查需要n步所以步长O（n）

对于频数最小的一定在哈夫曼树的第1（根为n层）层，所以总步数为n+n-1+n-2+。。。。+2 +1 即步长O(n^2)