【Hello AutoCAD 005】几个常用的绘图函数

    '创建直线
     Public Function addLine(ByVal startPt As Point3d, ByVal endPt As Point3d) As ObjectId
        '在内存中创建一个直线对象
         Dim LineEnt As New Line(startPt, endPt)
        '调用AppendEntity函数，将直线加入到模型空间
        Dim entID As ObjectId = AppendEntity(LineEnt)
        Return entID
    End Function 

    '创建圆
    Public Function addCircle(ByVal cenPt As Point3d, ByVal Radius As Double) As ObjectId
        '在内存中创建一个圆对象
        Dim Ent As New Circle(cenPt, Vector3d.ZAxis, Radius)
        Dim entID As ObjectId = AppendEntity(Ent)
        Return entID
    End Function 

    '创建圆弧【由圆心、半径、起始角度和终止角度创建圆弧】
    Public Function addArc(ByVal cenPt As Point3d, ByVal Radius As Double, ByVal startAng As Double, ByVal endAng As Double) As ObjectId
        '在内存中创建一个圆弧对象
        Dim Ent As New Arc(cenPt, Radius, startAng, endAng)
        Dim entID As ObjectId = AppendEntity(Ent)
        Return entID
    End Function
    '由二维点集合和线宽创建二维优化多线段函数
    Public Function addPline(ByVal Pts As Point2dCollection, ByVal Width As Double) As ObjectId
        Try
            '得到点集合的数量
            Dim n As Integer = Pts.Count
            '在内存中创建一个二维优化多线段对象
            Dim Ent As New Polyline(n)
            '向多线段添加顶点
            For i As Integer = 0 To n - 1
                Ent.AddVertexAt(i, Pts.Item(i), 0, Width, Width)
            Next
            Dim entID As ObjectId = AppendEntity(Ent)
            Return entid
        Catch ex As Exception
            '创建失败，则返回一个空的ObjectId
            Dim nullId As ObjectId = ObjectId.Null
            Return nullId
        End Try
    End Function 

'将图形对象加入到模型空间的函数
    Public Function AppendEntity(ByVal Ent As Entity) As ObjectId
        '得到当前文档的数据库对象
        Dim Db As Database = HostApplicationServices.WorkingDatabase
        Dim entID As ObjectId
        Using Trans As Transaction = Db.TransactionManager.StartTransaction()
            '以读方式打开块表
            Dim Bt As BlockTable = CType(Trans.GetObject(Db.BlockTableId, OpenMode.ForRead), BlockTable)
            '以写方式打开模型空间块表记录
            Dim Btr As BlockTableRecord = CType(Trans.GetObject(Bt.Item(BlockTableRecord.ModelSpace), OpenMode.ForWrite), BlockTableRecord)
            '将图形对象的信息加到块表记录中，并返回ObjectId对象
            entID = Btr.AppendEntity(Ent)
            '把直线添加到事物处理中
            Trans.AddNewlyCreatedDBObject(Ent, True)
            '提交事物处理
            Trans.Commit()
        End Using
        Return entID
    End Function