排序算法练习（二）

分治算法_求逆序对

AYYZOJ p1434

【问题描述】
　　给定一个序列a1,a2,…,an，如果存在i<j并且ai>aj，那么我们称之为逆序对，求逆序对的数目。
【输入格式】
　　第一行为n,表示序列长度，接下来的n行，第i+1行表示序列中的第i个数。
【输出格式】
　　所有逆序对总数。
【输入样例】
　　4
　　3
　　2
　　3
　　2
【输出样例】
　　3
【数据范围】
　　N<=10^5，Ai<=10^5。

思路：与归并排序联系起来。

分析：

    归并排序是将序列a[1,H]分成两部分——a[1,mid]和a[mid+1,H]分别进行归并排序，然后将这两部分合并起来。

    在合并的过程中（设1<=i<=mid,mid+1<=j<=H）,

          当a[i]<=a[j]时，并不产生逆序对；

          当a[i]>a[j]时，在前半部分a[1,mid]中，比a[i]大的数都比a[j]大，将a[j]放在a[i]前面的话，逆序数要加上mid-i+1.（i..mid 共有mid-i+1个数）

    因此，可以在归并排序中的合并过程中计算逆序对的数量。

var
  a,r:array[1..100000] of longint;
  i,n:longint;ans:int64;
procedure mergesort(s,t:longint);
  var
    m,i,j,k:longint;
  begin
    if s=t then exit;
    m:=(s+t) div 2;
    mergesort(s,m);
    mergesort(m+1,t);
    i:=s;
    j:=m+1;
    k:=s;
    while (i<=m) and (j<=t) do
      if a[i]<=a[j] then
        begin r[k]:=a[i];inc(i);inc(k);end
      else
        begin ans:=ans+m-i+1; r[k]:=a[j]; inc(j); inc(k);end;
    while i<=m do begin r[k]:=a[i]; inc(i); inc(k);end;
    while j<=t do begin r[k]:=a[j]; inc(j); inc(k);end;
    for i:=s to t do a[i]:=r[i];
  end;
begin
  readln(n);
  for i:=1 to n do readln(a[i]);
  mergesort(1,n);
  writeln(ans);
end.

排序算法_车厢重组

AYYZOJ p1437

这题的描述让人一眼觉得就是冒泡排序，老师说正解应该是归并，可是数据太弱，冒泡就水过了。

program p1437;
var
 n,i,j,t,k:longint;
 a:array[1..10000] of longint;
 flag:boolean;
begin
 readln(n);
 for i:=1 to n do read(a[i]);
  for j:=1 to n-1 do
   begin
    flag:=true;
    for i:=1 to n-j do
    if a[i]>a[i+1] then begin
       t:=a[i];a[i]:=a[i+1];a[i+1]:=t; inc(k);
        flag:=false; end;
    if flag then break;
   end;
 write(k);
end.