分治算法练习（一）

分治算法_小车问题

AYYZOJ p1428

COGS p559

具体讲解见此课件

//分治
program car1(input,output);
const zero=1e-4;
var s,a,b,c,c0,c1,t1,t2,t3,t4:real;
BEGIN
assign(input,'car.in');
assign(output,'car.out');
reset(input);
rewrite(output);
  readln(s,a,b);
  c0:=0;
  c1:=s;
  repeat
    c:=(c0+c1)/2;
    t3:=c/b;  //甲到K乘汽车用时；也是乙走到C用时。即 乙TAC=甲TAK
    t1:=t3+(s-c)/a;  //甲到终点用时。即 甲TAB
    t4:=(c-t3*a)/(a+b);  //乙从C走，车从K来接乙相遇用时。即 乙TCD
    t2:=t3+t4+(s-(t3+t4)*a)/b;   //乙到终点用时。即 乙TAB
    if t1<t2 then c1:=c else c0:=c;   //甲的时间短，走得快，则让汽车少载一段甲；乙的时间短，走得快，则让汽车多载一段甲
  until abs(t1-t2)<zero;
  writeln(t1:0:2);
close(input);
close(output)
end.

------------------------------------------------------------------
//数学
var
  s,a,b,k,x,t:real;
begin
assign(input,'car.in');
reset(input);
assign(output,'car.out');
rewrite(output);
  readln(s,a,b);
   k:=s*(a+b)/(3*a+b);
   t:=k/b+(s-k)/a;
  writeln(t:0:2);
close(input);close(output);
end.

分治算法_取余运算

AYYZOJ p1429

COGS p1130

具体讲解在这个课件中

program p1429;
var
 b,p,k,i,len,rest,temp:longint;
 binary:array[1..32] of longint;
begin
 readln(b,p,k);
 len:=0;
 temp:=p;
 while temp<>0 do
  begin
   len:=len+1;
   binary[len]:=temp mod 2;
   temp:=temp div 2;
  end;
  rest:=1;
  for i:=len downto 1 do
   begin
    temp:=rest*rest mod k;
    if binary[i]=1 then rest:=b mod k*temp mod k
                   else rest:=temp;
   end;
  writeln(b,'^',p,' mod ',k,'=',rest);
end.

Program cogs1130;
  Var
    B,P,K,ANS:Longint;
  Begin
    Assign(Input,'dmod.in');
    Assign(Output,'dmod.out');
    Reset(Input);
    Rewrite(Output);
    Readln(B,P,K);
    ANS:=1;
    B:=B Mod K;
    While P<>0 Do
      Begin
        If P And 1=1  {p mod 2=1} Then ANS:=ANS*B Mod K;
        P:=P Shr 1;   {p:=p div 2}{p:=p>>1}
        B:=B*B Mod K;
      End;
    Writeln(ANS);
    Close(Input);
    Close(Output);
  End.

分治算法_成绩排序

AYYZOJ p1431

program p1431;
Var a,b:array[1..10000] of longint;
  i,j,t,n:longint;flag:boolean;
Begin
 readln(n);
  for i:=1 to N do Readln(b[i],a[i]);
  for j:=1 to N-1 do begin
    flag:=true;
    for i:=1 to N-j do
      if a[i]>a[i+1] then begin
        t:=a[i];a[i]:=a[i+1];a[i+1]:=t;
        t:=b[i];b[i]:=b[i+1];b[i+1]:=t;
        flag:=false;
      end;
    if flag then break;
  end;
  for i:=1 to N do writeln(b[i],' ',a[i]);
end.

分治算法_循环比赛

AYYZOJ p1433

这个课件讲得很清楚了

program p1433;
var
 i,j,h,m,n:integer;
 a:array[1..100,1..100] of integer;
begin
 readln(m);
 n:=1; a[1,1]:=1; h:=1;
 for i:=1 to m do n:=n*2;
  repeat
   for i:=1 to h do
    for j:=1 to h do
    begin
     a[i,j+h]:=a[i,j]+h;
     a[i+h,j]:=a[i,j+h];
     a[i+h,j+h]:=a[i,j];
    end;
    h:=h*2;
   until h=n;
   for i:=1 to n do
    begin
     for j:=1 to n do write(a[i,j]:4); writeln;
    end;
end.

分治算法_棋子移动

AYYZOJ p1435

COGS p1161

这个课件讲得很清楚了

const max=100;
var n,st,sp:integer;
    c:array[1..max] of char;  {工作场所}

procedure print;  {打印}
  var i:integer;
  begin
    write('step',st:2,':');
    for i:=1 to 2*n+2 do write(c[i]);
    writeln;
    st:=st+1
  end;

procedure init(n:integer);  {初始化}
  var i:integer;
  begin
    st:=0;
    sp:=2*n+1;
    for i:=1 to n do c[i]:='o';
    for i:=n+1 to 2*n do c[i]:='*';
    c[2*n+1]:='-';c[2*n+2]:='-';
    print
  end;

procedure move(k:integer);  {移动一步}//将两个横线（空）移到k处（以左横线位置为序号）
  var j:integer;
  begin
    for j:=0 to 1 do begin c[sp+j]:=c[k+j];c[k+j]:='-';end;
    sp:=k;
    print
  end;

procedure mv(n:integer);    {主要过程}
  var i,k:integer;
  begin
    if n=4 then begin
                  move(4);
                  move(8);
                  move(2);
                  move(7);
                  move(1)
                end
           else begin
                  move(n);
                  move(2*n-1);
                  mv(n-1)
                end
  end;

begin  {main}
  assign(input,'chessman.in');
  assign(output,'chessman.out');
  reset(input);
  rewrite(output);
  readln(n);
  init(n);
  mv(n);
  close(input);
  close(output)
end.